Function Reference

_ClipBoard_GetFormatName

指定した登録形式の名前を取得します。

#Include <Clipboard.au3>
_ClipBoard_GetFormatName($iFormat)

 

パラメータ

$iFormat 取得する形式の型を指定します

 

返し値

成功: 形式名
Failure: 空文字列

 

注意

$ iFormatパラメータには事前定義されたクリップボード形式を指定しないでください

 

関連

 

こちらも参照

MSDNライブラリでGetClipboardFormatNameAを検索して下さい。

 


#include <GuiConstantsEx.au3>
#include <ClipBoard.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>

Opt('MustDeclareVars', 1)

Global $iMemo

_Main()

Func _Main()
    Local $hGUI, $iFormat

    ; GUI作成
    $hGUI = GUICreate("Clipboard", 600, 400)
    $iMemo = GUICtrlCreateEdit("", 2, 2, 596, 396, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; 新しいクリップボード形式を登録
    $iFormat = _ClipBoard_RegisterFormat ("AutoIt Library Text")
    If $iFormat = 0 Then _WinAPI_ShowError ("_ClipBoard_RegisterFormat failed")

    ; 新しい形式を表示
    MemoWrite(_ClipBoard_GetFormatName ($iFormat))

    ; ユーザーが終了させるまでループ
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main

; メモにメッセージを書き込む
Func MemoWrite($sMessage = "")
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite