現在のウィンドウステーションのクリップボードのシーケンス番号を取得します。
#Include <Clipboard.au3>
_ClipBoard_GetSequenceNumber()
パラメータ
なし。
返し値
| 成功: | クリップボードのシーケンス番号 |
| 失敗: | 0 |
注意
システムは 各ウィンドウステーションのクリップボードのシリアル番号を保持しています。この番号はクリップボードの内容に変更があった場合、クリップボードが空になった場合にインクリメントされます。この値を追跡することでクリップボード内容の変化を知り、データオブジェクトの作成を最適化することができます。クリップボードの描画が遅れる場合、変更が表示されるまでシーケンス番号はインクリメントされません。
関連
こちらも参照
MSDNライブラリでGetClipboardSequenceNumberを検索して下さい。
例
#include <GuiConstantsEx.au3>
#include <ClipBoard.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>
Opt('MustDeclareVars', 1)
Global $iMemo
_Main()
Func _Main()
Local $hGUI
; GUI作成
$hGUI = GUICreate("Clipboard", 600, 400)
$iMemo = GUICtrlCreateEdit("", 2, 2, 596, 396, $WS_VSCROLL)
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
GUISetState()
; クリップボードを開く
If Not _ClipBoard_Open ($hGUI) Then _WinAPI_ShowError ("_ClipBoard_Open failed")
ShowData($hGUI)
; クリップボードを閉じる
_ClipBoard_Close ()
; ユーザーが終了させるまでループ
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>_Main
; クリップボード情報を表示
Func ShowData($hGUI)
MemoWrite("GUI handle ............: " & $hGUI)
MemoWrite("Clipboard owner .......: " & _ClipBoard_GetOwner ())
MemoWrite("Clipboard open window .: " & _ClipBoard_GetOpenWindow ())
MemoWrite("Clipboard sequence ....: " & _ClipBoard_GetSequenceNumber ())
MemoWrite()
EndFunc ;==>ShowData
; メモにメッセージを書き込む
Func MemoWrite($sMessage = "")
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite