指定された高さ、幅で調整可能な矢印ラインのキャップを作成します。
#Include <GDIPlus.au3>
_GDIPlus_ArrowCapCreate($fHeight, $fWidth[, $bFilled = True])
パラメータ
| $fHeight | 矢尻の根元からの高さを単位長さで指定します。 |
| $fWidth | 矢尻の根元の幅を単位長さで指定します。 |
| $bFilled | [オプション]塗りつぶしフラグ: True - 矢印を塗りつぶします False - 矢印を塗りつぶしません |
返し値
| 成功: | 新しいArrowCapオブジェクトのハンドルを返します |
| 失敗: | 0 |
注意
オブジェクトを使い終わった後は_GDIPlus_ArrowCapDisposeを呼んでオブジェクトのリソースを解放してください。
関連
_GDIPlus_ArrowCapDispose
こちらも参照
MSDNライブラリでGdipCreateAdjustableArrowCapを検索して下さい。
例
#include <GuiConstantsEx.au3>
#include <GDIPlus.au3>
Opt('MustDeclareVars', 1)
_Main()
Func _Main()
Local $hGUI, $hGraphic, $hPen, $hEndCap
; GUI作成
$hGUI = GUICreate("GDI+", 400, 300)
GUISetState()
; リソースを作成
_GDIPlus_Startup ()
$hGraphic = _GDIPlus_GraphicsCreateFromHWND ($hGUI)
$hPen = _GDIPlus_PenCreate (0xFF000000, 2)
$hEndCap = _GDIPlus_ArrowCapCreate (3, 6)
_GDIPlus_PenSetCustomEndCap ($hPen, $hEndCap)
; ペンとキャップを表示
MsgBox(4096, "Information", "Pen end cap: 0x" & Hex(_GDIPlus_PenGetCustomEndCap ($hPen)))
; 矢印を描画
_GDIPlus_GraphicsDrawLine ($hGraphic, 10, 120, 390, 120, $hPen)
_GDIPlus_PenSetWidth ($hPen, 4)
_GDIPlus_GraphicsDrawLine ($hGraphic, 10, 150, 390, 150, $hPen)
_GDIPlus_PenSetWidth ($hPen, 6)
_GDIPlus_GraphicsDrawLine ($hGraphic, 10, 180, 390, 180, $hPen)
; ユーザーが終了するまでループ
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
; リソースを破棄
_GDIPlus_ArrowCapDispose ($hEndCap)
_GDIPlus_PenDispose ($hPen)
_GDIPlus_GraphicsDispose ($hGraphic)
_GDIPlus_Shutdown ()
EndFunc ;==>_Main