調整可能な矢印ラインのキャップのオブジェクトを解放します。
#Include <GDIPlus.au3>
_GDIPlus_ArrowCapDispose($hCap)
パラメータ
| $hCap | 調整可能な矢印ラインキャップオブジェクトのハンドル |
返し値
| 成功: | True |
| 失敗: | False |
注意
なし。
関連
_GDIPlus_ArrowCapCreate
こちらも参照
MSDNライブラリでのGdipDeleteCustomLineCapの検索結果
例
#include <GuiConstantsEx.au3>
#include <GDIPlus.au3>
Opt('MustDeclareVars', 1)
_Main()
Func _Main()
Local $hGUI, $hWnd, $hGraphic, $hPen, $hEndCap
; GUI作成
$hGUI = GUICreate("GDI+", 400, 300)
$hWnd = WinGetHandle("GDI+")
GUISetState()
; リソースを作成
_GDIPlus_Startup ()
$hGraphic = _GDIPlus_GraphicsCreateFromHWND ($hWnd)
$hPen = _GDIPlus_PenCreate (0xFF000000, 2)
$hEndCap = _GDIPlus_ArrowCapCreate (3, 6)
_GDIPlus_PenSetCustomEndCap ($hPen, $hEndCap)
; ペンとキャップを表示
MsgBox(4096, "Information", "Pen end cap: 0x" & Hex(_GDIPlus_PenGetCustomEndCap ($hPen)))
; 矢印を描画
_GDIPlus_GraphicsDrawLine ($hGraphic, 10, 120, 390, 120, $hPen)
_GDIPlus_PenSetWidth ($hPen, 4)
_GDIPlus_GraphicsDrawLine ($hGraphic, 10, 150, 390, 150, $hPen)
_GDIPlus_PenSetWidth ($hPen, 6)
_GDIPlus_GraphicsDrawLine ($hGraphic, 10, 180, 390, 180, $hPen)
; ユーザーが終了するまでループ
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
; リソースを破棄
_GDIPlus_ArrowCapDispose ($hEndCap)
_GDIPlus_PenDispose ($hPen)
_GDIPlus_GraphicsDispose ($hGraphic)
_GDIPlus_Shutdown ()
EndFunc ;==>_Main