StringFormatオブジェクトを作成します。
#Include <GDIPlus.au3>
_GDIPlus_StringFormatCreate([$iFormat = 0[, $iLangID = 0]])
パラメータ
| $iFormat | [オプション]フォーマットフラグ。次の1つまたは組み合わせです: 0x0001 - 文字列方向を右から左に向かう方向に指定します 0x0002 - テキストの各行がディスプレイデバイス上で垂直方向に描画されるように指定します 0x0004 - 文字の一部が文字列のレイアウト長方形からはみ出ることを許可するよう指定します 0x0020 - Unicodeのレイアウト制御文字を表す文字が表示されるよう指定します 0x0400 - 要求されたフォントでサポートされていない文字で代わりのフォントを使用するよう指定します 0x0800 - 各行の末尾のスペースも文字列の長さに含めるよう指定します 0x1000 - テキストの次行への丸め込みを無効にするよう指定します 0x2000 - レイアウト長方形内におさまっている行のみ指定します 0x4000 - レイアウト長方形にからはみ出た文字、レイアウト長方形の外側に伸びるテキストも表示するよう指定します |
| $iLangID | [オプション]使用言語 |
返し値
| 成功: | StringFormatオブジェクトのハンドル |
| 失敗: | 0 |
注意
StringFormatオブジェクトの使用後は_GDIPlus_StringFormatDisposeを呼んでリソースを解放してください。
関連
_GDIPlus_StringFormatDispose, _GDIPlus_StringFormatSetAlign
こちらも参照
MSDNライブラリでGdipCreateStringFormatを検索して下さい。
例
#include <GuiConstantsEx.au3>
#include <GDIPlus.au3>
Opt('MustDeclareVars', 1)
_Main()
Func _Main()
Local $hGUI, $hGraphic, $hBrush, $hFormat, $hFamily, $hFont, $tLayout
; GUI作成
$hGUI = GUICreate("GDI+", 400, 300)
GUISetState()
; 文字列を描画
_GDIPlus_Startup ()
$hGraphic = _GDIPlus_GraphicsCreateFromHWND ($hGUI)
$hBrush = _GDIPlus_BrushCreateSolid (0xFF00007F)
$hFormat = _GDIPlus_StringFormatCreate ()
$hFamily = _GDIPlus_FontFamilyCreate ("Arial")
$hFont = _GDIPlus_FontCreate ($hFamily, 12, 2)
$tLayout = _GDIPlus_RectFCreate (140, 110, 100, 20)
_GDIPlus_GraphicsDrawStringEx ($hGraphic, "Hello world", $hFont, $tLayout, $hFormat, $hBrush)
; ユーザーが終了するまでループ
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
; リソースを破棄
_GDIPlus_FontDispose ($hFont)
_GDIPlus_FontFamilyDispose ($hFamily)
_GDIPlus_StringFormatDispose ($hFormat)
_GDIPlus_BrushDispose ($hBrush)
_GDIPlus_GraphicsDispose ($hGraphic)
_GDIPlus_ShutDown ()
EndFunc ;==>_Main