Function Reference

_GDIPlus_StringFormatSetAlign

StringFormatオブジェクトのテキスト配置を設定します。

#Include <GDIPlus.au3>
_GDIPlus_StringFormatSetAlign($hStringFormat,$iFlag)

 

パラメータ

$hStringFormat 配置設定をおこなうStringFormatオブジェクト
$iFlags 配置は次のうちのいずれかです:
0 - テキストは左揃えになります。
1 - テキストは中央揃えになります。
2 - テキストは右揃えになります。

 

返し値

成功: 1
失敗: 0を返し、@errorに1を設定します

 

注意

なし。

 

関連

_GDIPlus_StringFormatCreate

 

こちらも参照

MSDNライブラリでGdipSetStringFormatAlignを検索して下さい。

 


#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>

$hWnd = GUICreate("GDI+ Example", 400, 300)
GUISetState()

_GDIPlus_Startup()
$hGraphics = _GDIPlus_GraphicsCreateFromHWND($hWnd)
_GDIPlus_GraphicsClear($hGraphics)

$hBrush = _GDIPlus_BrushCreateSolid(0xFF009900)
$hFamily = _GDIPlus_FontFamilyCreate("Arial")
$hFont = _GDIPlus_FontCreate($hFamily, 36)
$hLayout = _GDIPlus_RectFCreate(0, 0, 400, 300)
$hStringFormat = _GDIPlus_StringFormatCreate()
_GDIPlus_StringFormatSetAlign($hStringFormat, 1)
_GDIPlus_GraphicsDrawStringEx($hGraphics, "AutoIt Rocks", $hFont, $hLayout, $hStringFormat, $hBrush)

Do
    $msg = GUIGetMsg()
Until $msg = $GUI_EVENT_CLOSE


_GDIPlus_BrushDispose($hBrush)
_GDIPlus_FontFamilyDispose($hFamily)
_GDIPlus_FontDispose($hFont)
_GDIPlus_StringFormatDispose($hStringFormat)
_GDIPlus_GraphicsDispose($hGraphics)
_GDIPlus_Shutdown()