文字列を追加します。
#Include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_AddString($hWnd, $sText[, $iImage = -1[, $iSelecteImage = -1[, $iOverlayImage = -1[, $iIndent = -1[, $iParam = -1]]]]])
パラメータ
| $hWnd | コントロールのハンドル リストの最後にアイテムを挿入する場合は$iIndexを-1に設定します。 |
| $sText | アイテムテキスト。-1に設定するとアイテム設定は$CBEN_GETDISPINFO通知メッセージを介して設定されます。 |
| $iImage | [オプション]コントロールの画像リスト内のアイテムアイコンのゼロ始まりのインデックス |
| $iSelecteImage | [オプション]コントロールの画像リスト内のアイテムアイコンのゼロ始まりのインデックス |
| $iOverlayImage | [オプション]コントロールの画像リスト内のアイテムアイコンのゼロ始まりのインデックス |
| $iIndent | [オプション]アイテムをインデントする際の画像幅数。1インデントは画像の幅と同じです。 |
| $iParam | [オプション]アイテム固有の値 |
返し値
| 成功: | 新しいアイテムのインデックス |
| 失敗: | -1 |
注意
なし。
関連
_GUICtrlComboBoxEx_DeleteString, _GUICtrlComboBoxEx_InitStorage
例
#include <GuiComboBoxEx.au3>
#include <GuiImageList.au3>
#include <GuiConstantsEx.au3>
Opt('MustDeclareVars', 1)
$Debug_CB = False ; ComboBox/ComboBoxEx関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用
_Main()
Func _Main()
Local $hGUI, $hImage, $hCombo
; GUIを作成
$hGUI = GUICreate("ComboBoxEx Add String", 400, 300)
$hCombo = _GUICtrlComboBoxEx_Create ($hGUI, "", 2, 2, 394, 100)
GUISetState()
$hImage = _GUIImageList_Create (16, 16, 5, 3)
For $x = 0 To 146
_GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", $x)
Next
_GUIImageList_Add ($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap ($hCombo, 0xFF0000, 16, 16))
_GUIImageList_Add ($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap ($hCombo, 0x00FF00, 16, 16))
_GUIImageList_Add ($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap ($hCombo, 0x0000FF, 16, 16))
_GUICtrlComboBoxEx_SetImageList ($hCombo, $hImage)
_GUICtrlComboBoxEx_InitStorage ($hCombo, 150, 300)
_GUICtrlComboBoxEx_BeginUpdate ($hCombo)
For $x = 0 To 149
_GUICtrlComboBoxEx_AddString ($hCombo, StringFormat("%03d : Random string", Random(1, 200, 1)), $x, $x)
Next
_GUICtrlComboBoxEx_EndUpdate ($hCombo)
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>_Main