検索ダイアログを初期化します。
#Include <GuiEdit.au3>
_GUICtrlEdit_Find($hWnd[, $fReplace = False])
パラメータ
| $hWnd | コントロールのハンドル |
| $fReplace | [オプション]置換オプション: True - オプションを表示 False - オプションを非表示 |
返し値
なし。
注意
エディットコントロールのテキストを使用してそのテキストを置換した場合、この関数は正しく機能しません。
関連
例
#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiEdit.au3>
#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
Opt('MustDeclareVars', 1)
$Debug_Ed = False ; Edit関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用
Example_Internal()
Example_External()
Func Example_Internal()
Local $s_texttest = "this is a test" & @CRLF & _
"this is only a test" & @CRLF & _
"this testing should work for you as well as it does for me"
Local $Button1, $Button2, $msg, $hEdit
GUICreate('Find And Replace Example with AutoIt ' & FileGetVersion(@AutoItExe), 622, 448, 192, 125)
$hEdit = GUICtrlCreateEdit($s_texttest, 64, 24, 505, 233, _
BitOR($ES_AUTOVSCROLL, $WS_VSCROLL, $ES_MULTILINE, $WS_HSCROLL, $ES_NOHIDESEL))
$Button1 = GUICtrlCreateButton("Find", 176, 288, 121, 33, 0)
$Button2 = GUICtrlCreateButton("Find And Replace", 368, 288, 121, 33, 0)
GUISetState()
While 1
$msg = GUIGetMsg()
Select
Case $msg = $GUI_EVENT_CLOSE
ExitLoop
Case $msg = $Button1
_GUICtrlEdit_Find($hEdit)
Case $msg = $Button2
_GUICtrlEdit_Find($hEdit, True)
Case Else
;;;;;;;
EndSelect
WEnd
GUIDelete()
EndFunc ;==>Example_Internal
Func Example_External()
Local $s_texttest = 'Find And Replace Example with AutoIt ' & FileGetVersion(@AutoItExe) & @LF & _
"this is a test" & @LF & _
"this is only a test" & @LF & _
"this testing should work for you as well as it does for me"
Local $whandle, $handle
Local $Title = "[CLASS:Notepad]"
Run("notepad", "", @SW_MAXIMIZE)
; "Untitled"というウィンドウが現れるまで待機
WinWait($Title)
; メモ帳ウィンドウのハンドルを取得
$whandle = WinGetHandle($Title)
If @error Then
MsgBox(4096, "Error", "Could not find the correct window")
Else
$handle = ControlGetHandle($whandle, "", "Edit1")
If @error Then
MsgBox(4096, "Error", "Could not find the correct control")
Else
; ウィンドウのエディットコントロールにテキストを直接送信
ControlSend($whandle, "", "Edit1", $s_texttest)
_GUICtrlEdit_Find($handle, True)
EndIf
EndIf
EndFunc ;==>Example_External