Function Reference

_GUICtrlEdit_FmtLines

エディットコントロールにソフト改行文字が含まれているかどうかを判定します。

#Include <GuiEdit.au3>
_GUICtrlEdit_FmtLines($hWnd[, $fSoftBreak = False])

 

パラメータ

$hWnd コントロールのハンドル
$fSoftBreak [オプション]ソフト改行文字が挿入されるかどうかを指定します:
 True - 文字を挿入します
False - 文字を取り除きます

 

返し値

成功: $fSoftBreakパラメータと同じ値

 

注意

ソフト改行は2つのキャリッジリターンとラインフィードで構成され、ワードラップによって区切られる行末に挿入されます。

この関数は_GUICtrlEdit_GetText関数によって返されるテキストにのみ有効です。

エディットコントロール内のテキスト表示には影響しません。

_GUICtrlEdit_FmtLines関数は ハード改行で終わる行には効果がありません。
ハード改行は1つのキャリッジリターンとラインフィードで構成されます。

 

関連

 


#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiEdit.au3>
#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>

Opt('MustDeclareVars', 1)

$Debug_Ed = False ; Edit関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用

_Main()

Func _Main()
    Local $hEdit
    Local $Wow64 = ""
    If @AutoItX64 Then $Wow64 = "\Wow6432Node"
    Local $sFile = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE" & $Wow64 & "\AutoIt v3\AutoIt", "InstallDir") & "\include\changelog.txt"
    Local $sBefore, $sAfter

    ; GUI作成
    GUICreate("Edit FmtLines", 400, 300)
    $hEdit = GUICtrlCreateEdit("", 2, 2, 394, 268, BitOR($ES_WANTRETURN, $WS_VSCROLL))
    GUISetState()

    ; テキストを設定
    _GUICtrlEdit_SetText($hEdit, FileRead($sFile, 500))

    ; テキストはデフォルトフォーマットで取得される
    $sBefore = _GUICtrlEdit_GetText($hEdit)

    ; ソフト改行を挿入
    _GUICtrlEdit_FmtLines($hEdit, True)

    ; ソフト改行を含むテキスト
    $sAfter = _GUICtrlEdit_GetText($hEdit)

    MsgBox(4096, "Information", "Before:" & @LF & @LF & $sBefore & @LF & _
            '--------------------------------------------------------------' & @LF & _
            "After:" & @LF & @LF & $sAfter)

    ; ユーザーが終了するまでループ
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main