Function Reference

_GUICtrlEdit_InsertText

テキストを挿入します。

#Include <GuiEdit.au3>
_GUICtrlEdit_InsertText($hWnd, $sText, $iIndex = -1)

 

パラメータ

$hWnd コントロールのハンドル
$sText 挿入する文字列
$iIndex 挿入する文字位置

 

返し値

なし。

 

注意

なし。

 

関連

_GUICtrlEdit_AppendText

 


#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiEdit.au3>
#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>

Opt('MustDeclareVars', 1)

$Debug_Ed = False ; Edit関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用

_Main()

Func _Main()
    Local $hEdit
    Local $Wow64 = ""
    If @AutoItX64 Then $Wow64 = "\Wow6432Node"
    Local $sFile = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE" & $Wow64 & "\AutoIt v3\AutoIt", "InstallDir") & "\include\changelog.txt"

    ; GUI作成
    GUICreate("Edit Insert Text", 400, 300)
    $hEdit = GUICtrlCreateEdit("", 2, 2, 394, 268, BitOR($ES_WANTRETURN, $WS_VSCROLL))
    GUISetState()

    ; 余白を設定
    _GUICtrlEdit_SetMargins($hEdit, BitOR($EC_LEFTMARGIN, $EC_RIGHTMARGIN), 10, 10)

    ; テキストを設定
    _GUICtrlEdit_SetText($hEdit, FileRead($sFile))

    ; テキストを挿入
    _GUICtrlEdit_InsertText($hEdit, "*** Excellent UDFs ***" & @CRLF & @CRLF, 0)

    ; ユーザーが終了するまでループ
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main