読み取り専用属性($ES_READONLY)を設定または解除します。
#Include <GuiEdit.au3>
_GUICtrlEdit_SetReadOnly($hWnd, $fReadOnly)
パラメータ
| $hWnd | コントロールのハンドル |
| $fReadOnly | 次の値: True - $ES_READONLYスタイルを設定します False - $ES_READONLYスタイルを解除します |
返し値
| 成功: | True |
| 失敗: | False |
注意
なし。
関連
例
#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiEdit.au3>
#include <GuiStatusBar.au3>
#include <GuiConstantsEx.au3>
Opt('MustDeclareVars', 1)
$Debug_Ed = False ; Edit関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用
_Main()
Func _Main()
Local $StatusBar, $hEdit, $hGUI
Local $Wow64 = ""
If @AutoItX64 Then $Wow64 = "\Wow6432Node"
Local $sFile = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE" & $Wow64 & "\AutoIt v3\AutoIt", "InstallDir") & "\include\changelog.txt"
Local $aPartRightSide[4] = [120, 248, 378, -1]
; GUI作成
$hGUI = GUICreate("Edit Set Read Only", 400, 300)
$hEdit = GUICtrlCreateEdit("", 2, 2, 394, 268)
$StatusBar = _GUICtrlStatusBar_Create($hGUI, $aPartRightSide)
_GUICtrlStatusBar_SetIcon($StatusBar, 3, 97, "shell32.dll")
GUISetState()
; 余白を設定
_GUICtrlEdit_SetMargins($hEdit, BitOR($EC_LEFTMARGIN, $EC_RIGHTMARGIN), 10, 10)
; テキストを追加
_GUICtrlEdit_SetText($hEdit, FileRead($sFile))
_GUICtrlEdit_LineScroll($hEdit, 0, _GUICtrlEdit_GetLineCount($hEdit) * - 1)
; 変更フラグを取得
_GUICtrlStatusBar_SetText($StatusBar, "Modified: " & _GUICtrlEdit_GetModify($hEdit), 2)
; 読み取り専用に設定
_GUICtrlEdit_SetReadOnly($hEdit, True)
; ユーザーが終了するまでループ
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>_Main