Function Reference

_GUICtrlEdit_SetSel

文字の一定範囲を選択します。

#Include <GuiEdit.au3>
_GUICtrlEdit_SetSel($hWnd, $iStart, $iEnd)

パラメータ

$hWnd	コントロールのハンドル
$iStart	選択の開始文字の位置指定します。
$iEnd	選択の終了文字の位置指定します。

返し値

なし。

注意

開始値は終了値より大きくてもかまいません。
2つの値のうち小さい方の値が選択部の最初の文字の位置を指定し、
大きい値が選択部の最後の文字の位置を指定します。

最初の値は選択部のアンカーポイントであり、終了値はアクティブエンドです。
ユーザーが選択範囲を調整するためにSHIFTキーを使用すると、アクティブエンドが移動しアンカーポイントはそのままです。

$iStartが0で$iEndが-1の場合、エディットコントロール内の全てのテキストが選択されます。
$iStartが-1の場合、現在選択されている範囲の選択が解除されます。

$iStartと$iEndの相対値によらずコントロールの$iEnd位置には点滅するキャレットが表示されます。

例

#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiEdit.au3>
#include <GuiStatusBar.au3>
#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>

Opt('MustDeclareVars', 1)

$Debug_Ed = False ; Edit関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用

_Main()

Func _Main()
Local $StatusBar, $hEdit, $hGUI
Local $Wow64 = ""
If @AutoItX64 Then $Wow64 = "\Wow6432Node"
Local $sFile = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE" & $Wow64 & "\AutoIt v3\AutoIt", "InstallDir") & "\include\changelog.txt"
Local $aPartRightSide[3] = [190, 378, -1], $aSel

; GUI作成
$hGUI = GUICreate("Edit Set Sel", 400, 300)
$hEdit = GUICtrlCreateEdit("", 2, 2, 394, 268, BitOR($ES_WANTRETURN, $WS_VSCROLL))
$StatusBar = _GUICtrlStatusBar_Create($hGUI, $aPartRightSide)
_GUICtrlStatusBar_SetIcon($StatusBar, 2, 97, "shell32.dll")
GUISetState()

; 余白を設定
_GUICtrlEdit_SetMargins($hEdit, BitOR($EC_LEFTMARGIN, $EC_RIGHTMARGIN), 10, 10)

; テキストを設定
_GUICtrlEdit_SetText($hEdit, FileRead($sFile))

; 選択部を設定
_GUICtrlEdit_SetSel($hEdit, 15, 20)

; 選択部を取得
$aSel = _GUICtrlEdit_GetSel($hEdit)
_GUICtrlStatusBar_SetText($StatusBar, "Start: " & $aSel[0])
_GUICtrlStatusBar_SetText($StatusBar, "End: " & $aSel[1], 1)

; ユーザーが終了するまでループ
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>_Main

Guiエディット管理一覧

AutoItUDFsドキュメント日本語訳 - トップ