アイテムテキスト内に指定されたテキストを含むアイテムを検索します。
#Include <GuiListBox.au3>
_GUICtrlListBox_FindInText($hWnd, $sText[, $iStart = -1[, $fWrapOK = True]])
パラメータ
| $hWnd | コントロールのハンドル |
| $sText | 検索テキスト |
| $iStart | [オプション]検索を開始する位置のアイテムのゼロ始まりのインデックス。-1を指定すると先頭から開始します。 指定されたアイテム自体は検索の対象になりません。 |
| $fWrapOK | [オプション]Trueの場合、一致するものがみつからないと先頭のアイテムから検索を続行します |
返し値
| 成功: | アイテムのゼロ始まりのインデックス |
| 失敗: | -1 |
注意
検索では大文字小文字は区別されません。
関連
_GUICtrlListBox_FindString, _GUICtrlListBox_SelectString
例
#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GUIListBox.au3>
#include <GuiConstantsEx.au3>
Opt('MustDeclareVars', 1)
$Debug_LB = False ; ListBox関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用
_Main()
Func _Main()
Local $iIndex, $hListBox
; GUIを作成
GUICreate("List Box Find In Text", 400, 296)
$hListBox = GUICtrlCreateList("", 2, 2, 396, 296)
GUISetState()
; 文字列を追加
_GUICtrlListBox_BeginUpdate($hListBox)
For $iI = 1 To 9
_GUICtrlListBox_AddString($hListBox, StringFormat("%03d : Random string", Random(1, 100, 1)))
Next
_GUICtrlListBox_InsertString($hListBox, "eXaCt tExT", 3)
_GUICtrlListBox_EndUpdate($hListBox)
; アイテムを見つける
$iIndex = _GUICtrlListBox_FindInText($hListBox, "exa")
_GUICtrlListBox_SetCurSel($hListBox, $iIndex)
; ユーザーが終了するまでループ
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>_Main