指定された特性でアイテムを検索します。
#Include <GuiListView.au3>
_GUICtrlListView_FindItem($hWnd, $iStart, ByRef $tFindInfo[, $sText = ""])
パラメータ
| $hWnd | コントロールのハンドル |
| $iStart | 検索開始位置のアイテムのゼロ始まりのインデックス。-1の場合は先頭から検索します。 指定されたアイテム自体は検索対象に含まれません。 |
| $tFindInfo | 検索情報を格納した$tagLVFINDINFO構造体 |
| $sText | [オプション]アイテムテキストと比較される文字列。 $LVFI_STRINGまたは$LVFI_PARTIALがFlagsメンバーに設定されている際のみ有効です。 |
返し値
| 成功: | アイテムのゼロ始まりのインデックス |
| 失敗: | -1 |
注意
なし。
関連
_GUICtrlListView_FindParam, _GUICtrlListView_FindNearest, $tagLVFINDINFO
例
#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiConstantsEx.au3>
#include <GuiListView.au3>
Opt('MustDeclareVars', 1)
$Debug_LV = False ; ListView関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用
_Main()
Func _Main()
Local $tInfo, $iI, $hListView
GUICreate("ListView Find Item", 400, 300)
$hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
GUISetState()
; 列を追加
_GUICtrlListView_AddColumn($hListView, "Items", 100)
; アイテムを追加
_GUICtrlListView_BeginUpdate($hListView)
For $iI = 1 To 100
_GUICtrlListView_AddItem($hListView, "Item " & $iI)
Next
_GUICtrlListView_EndUpdate($hListView)
; アイテム50のパラメータ値を設定
_GUICtrlListView_SetItemParam($hListView, 49, 1234)
; ターゲットアイテムを検索
$tInfo = DllStructCreate($tagLVFINDINFO)
DllStructSetData($tInfo, "Flags", $LVFI_PARAM)
DllStructSetData($tInfo, "Param", 1234)
$iI = _GUICtrlListView_FindItem($hListView, -1, $tInfo)
MsgBox(4160, "Information", "Target Item Index: " & $iI)
_GUICtrlListView_EnsureVisible($hListView, $iI)
; ユーザーが終了するまでループ
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>_Main