Function Reference

_GUICtrlListView_FindParam

指定されたlParamのアイテムを検索します。

#Include <GuiListView.au3>
_GUICtrlListView_FindParam($hWnd, $iParam[, $iStart = -1])

 

パラメータ

$hWnd コントロールのハンドル
$iParam 検索するパラメータ値
$iStart [オプション]検索開始位置のアイテムのゼロ始まりのインデックス。先頭から検索するには-1にします。
指定されたアイテム自体は検索対象になりません。

 

返し値

成功: アイテムのゼロ始まりのインデックス
失敗: -1

 

注意

なし。

 

関連

_GUICtrlListView_FindItem

 


#include <GuiConstantsEx.au3>
#include <GuiListView.au3>

Opt('MustDeclareVars', 1)

$Debug_LV = False ; ListView関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用

; 警告:SetItemParamをGuiCtrlCreateListViewItemで作成されたアイテムに使用しないこと
; ParamはアイテムのコントロールIDである

_Main()

Func _Main()
    Global $GUI, $iI, $hListView

    ; GUIを作成
    $GUI = GUICreate("(UDF Created) ListView Find Param", 400, 300)
    $hListView = _GUICtrlListView_Create($GUI, "", 2, 2, 394, 268)
    GUISetState()

    ; 列を追加
    _GUICtrlListView_AddColumn($hListView, "Items", 100)

    ; アイテムを追加
    _GUICtrlListView_BeginUpdate($hListView)
    For $iI = 1 To 100
        _GUICtrlListView_AddItem($hListView, "Item " & $iI)
    Next
    _GUICtrlListView_EndUpdate($hListView)

    ; アイテム50のパラメータ値を設定
    _GUICtrlListView_SetItemParam($hListView, 49, 1234)

    ; ターゲットアイテムを検索
    $iI = _GUICtrlListView_FindParam($hListView, 1234)
    MsgBox(4160, "Information", "Target Item Index: " & $iI)
    _GUICtrlListView_EnsureVisible($hListView, $iI)

    ; ユーザーが終了するまでループ
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main