レバーコントロールに新しいバンドを追加します。
#Include <GuiRebar.au3>
_GUICtrlRebar_AddBand($hwndRebar, $hwndChild[, $iMinWidth = 100[, $iDefaultWidth = 100[, $sText = ""[, $iIndex = -1[, $fStyle = -1]]]]])
パラメータ
| $hwndRebar | レバーコントロールのハンドル |
| $hwndChild | 追加するコントロールのハンドル |
| $iMinWidth | [オプション]バンドの最小幅 |
| $iDefaultWidth | [オプション]ピクセル単位でのバンドの長さ |
| $sText | [オプション]バンドの表示テキスト |
| $iIndex | [オプション]バンドが挿入される位置のゼロ始まりのインデックス このパラメータを-1に設定するとコントロールは新しいバンドを最後の位置に追加します |
| $fStyle | [オプション]バンドの種類を指定するフラグ。この値は次のものの組み合わせです: $RBBS_BREAK - 新しい行にバンドがきます。 $RBBS_CHILDEDGE - バンドは子ウィンドウの上部と下部に縁を持ちます。 $RBBS_FIXEDBMP - バンドがサイズ変更された際に背景ビットマップが動かないようにします。 $RBBS_FIXEDSIZE - バンドのサイズ変更をできなくします。このスタイルではバンド上にサイズ変更用グリップが表示されません。 $RBBS_GRIPPERALWAYS - バージョン4.71。レバーの中にバンドが1つだけしかない場合でも、常にサイズ変更用グリップが表示されます。 $RBBS_HIDDEN - バンドは表示されません。 $RBBS_NOGRIPPER - バージョン4.71。レバーの中にバンドが複数ある場合でも、常にサイズ変更用グリップは表示されません。 $RBBS_USECHEVRON - バージョン5.80。バンドがcxIdealよりも小さくなった場合にシェブロンボタンを表示します。 $RBBS_VARIABLEHEIGHT - バージョン4.71。レバーコントロールによってバンドのサイズ変更ができるようにします。 レバーがどのようにバンドのサイズ変更をおこなうかはcyIntegralとcyMaxChildに依存します。 $RBBS_NOVERT - 垂直時に表示しません。 $RBBS_USECHEVRON - ドロップダウンボタンを表示します。 $RBBS_HIDETITLE - バンドタイトルを表示しません。 $RBBS_TOPALIGN - バンドを最上段に固定します。 |
返し値
| 成功: | True |
| 失敗: | False |
注意
なし。
関連
_GUICtrlRebar_AddToolBarBand, _GUICtrlRebar_DeleteBand
例
#include <GuiReBar.au3>
#include <GuiComboBox.au3>
#include <GuiDateTimePicker.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>
#include <GuiConstantsEx.au3>
Opt("MustDeclareVars", 1)
$Debug_RB = False
_Main()
Func _Main()
Local $hgui, $btnExit, $hCombo, $hReBar, $hDTP, $hInput
$hgui = GUICreate("Rebar", 400, 396, -1, -1, BitOR($WS_MINIMIZEBOX, $WS_CAPTION, $WS_POPUP, $WS_SYSMENU, $WS_MAXIMIZEBOX))
; レバーコントロールを作成
$hReBar = _GUICtrlReBar_Create($hgui, BitOR($CCS_TOP, $WS_BORDER, $RBS_VARHEIGHT, $RBS_AUTOSIZE, $RBS_BANDBORDERS))
; レバーに挿入するコンボボックスを作成
$hCombo = _GUICtrlComboBox_Create($hgui, "", 0, 0, 120)
_GUICtrlComboBox_BeginUpdate($hCombo)
_GUICtrlComboBox_AddDir($hCombo, @WindowsDir & "\*.exe")
_GUICtrlComboBox_EndUpdate($hCombo)
; レバーに挿入する日付け時刻ピッカーを作成
$hDTP = _GUICtrlDTP_Create($hgui, 0, 0, 190)
; レバーに挿入する入力ボックスを作成
$hInput = GUICtrlCreateInput("Input control", 0, 0, 120, 20)
; コントロールにバンドを追加
_GUICtrlReBar_AddBand($hReBar, $hCombo, 120, 200, "Dir *.exe")
; 追加し、2行目にさせる
_GUICtrlReBar_AddBand($hReBar, $hDTP, 120)
_GUICtrlRebar_SetBandStyleBreak($hReBar, 1)
; レバーのはじめに追加
_GUICtrlReBar_AddBand($hReBar, GUICtrlGetHandle($hInput), 120, 200, "Name:", 0)
$btnExit = GUICtrlCreateButton("Exit", 150, 360, 100, 25)
GUISetState(@SW_SHOW)
While 1
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE, $btnExit
Exit
EndSwitch
WEnd
EndFunc ;==>_Main