レバーコントロールに新しいバンドを追加します。
#Include <GuiRebar.au3>
_GUICtrlRebar_AddToolBarBand($hwndRebar, $hwndToolbar[, $sText = ""[, $iIndex = -1[, $fStyle = -1]]])
パラメータ
| $hwndRebar | レバーコントロールのハンドル |
| $hwndToolbar | 追加するツールバーコントロールのハンドル |
| $sText | [オプション]バンドの表示テキスト |
| $iIndex | [オプション]バンドが挿入される位置のゼロ始まりのインデックス このパラメータを-1に設定するとコントロールは新しいバンドを最後の位置に追加します |
| $fStyle | [オプション]バンドの種類を指定するフラグ。この値は次のものの組み合わせです: $RBBS_BREAK - 新しい行にバンドがきます。 $RBBS_CHILDEDGE - バンドは子ウィンドウの上部と下部に縁を持ちます。 $RBBS_FIXEDBMP - バンドがサイズ変更された際に背景ビットマップが動かないようにします。 $RBBS_FIXEDSIZE - バンドのサイズ変更をできなくします。このスタイルではバンド上にサイズ変更用グリップが表示されません。 $RBBS_GRIPPERALWAYS - バージョン4.71。レバーの中にバンドが1つだけしかない場合でも、常にサイズ変更用グリップが表示されます。 $RBBS_HIDDEN - バンドは表示されません。 $RBBS_NOGRIPPER - バージョン4.71。レバーの中にバンドが複数ある場合でも、常にサイズ変更用グリップは表示されません。 $RBBS_USECHEVRON - バージョン5.80。バンドがcxIdealよりも小さくなった場合にシェブロンボタンを表示します。 $RBBS_VARIABLEHEIGHT - バージョン4.71。レバーコントロールによってバンドのサイズ変更ができるようにします。 レバーがどのようにバンドのサイズ変更をおこなうかはcyIntegralとcyMaxChildに依存します。 $RBBS_NOVERT - 垂直時に表示しません。 $RBBS_USECHEVRON - ドロップダウンボタンを表示します。 $RBBS_HIDETITLE - バンドタイトルを表示しません。 $RBBS_TOPALIGN - バンドを最上段に固定します。 |
返し値
| 成功: | True |
| 失敗: | False |
注意
なし。
関連
_GUICtrlRebar_AddBand, _GUICtrlRebar_DeleteBand
例
#include <GuiConstantsEx.au3>
#include <GuiReBar.au3>
#include <GuiToolBar.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>
Opt("MustDeclareVars", 1)
$Debug_RB = False
_Main()
Func _Main()
Local $hgui, $btnExit, $hToolbar, $hReBar, $hInput
Local Enum $idNew = 1000, $idOpen, $idSave, $idHelp
$hgui = GUICreate("Rebar", 400, 396, -1, -1, BitOR($WS_MINIMIZEBOX, $WS_CAPTION, $WS_POPUP, $WS_SYSMENU, $WS_MAXIMIZEBOX))
; レバーコントロールを作成
$hReBar = _GUICtrlReBar_Create($hgui, BitOR($CCS_TOP, $WS_BORDER, $RBS_VARHEIGHT, $RBS_AUTOSIZE, $RBS_BANDBORDERS))
; レバーに挿入するツールバーを作成
$hToolbar = _GUICtrlToolBar_Create($hgui, BitOR($TBSTYLE_FLAT, $CCS_NORESIZE, $CCS_NOPARENTALIGN))
; 標準システムビットマップを追加
Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
Case 0
_GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
Case 2
_GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
EndSwitch
; ボタンを追加
_GUICtrlToolbar_AddButton($hToolbar, $idNew, $STD_FILENEW)
_GUICtrlToolbar_AddButton($hToolbar, $idOpen, $STD_FILEOPEN)
_GUICtrlToolbar_AddButton($hToolbar, $idSave, $STD_FILESAVE)
_GUICtrlToolbar_AddButtonSep($hToolbar)
_GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)
; レバーに挿入する入力ボックスを作成
$hInput = GUICtrlCreateInput("Input control", 0, 0, 120, 20)
; コントロールを格納しているバンドを追加
_GUICtrlReBar_AddBand($hReBar, GUICtrlGetHandle($hInput), 120, 200, "Name:")
; コントロールを格納しているバンドをレバーの最初に追加
_GUICtrlReBar_AddToolBarBand($hReBar, $hToolbar, "", 0)
$btnExit = GUICtrlCreateButton("Exit", 150, 360, 100, 25)
GUISetState(@SW_SHOW)
While 1
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE, $btnExit
Exit
EndSwitch
WEnd
EndFunc ;==>_Main