(最初の)選択された段落、または(選択されていない場合)現在の段落の番号付けスタイルを取得します。
#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetParaNumbering($hWnd)
パラメータ
| $hWnd | コントロールのハンドル |
返し値
| 成功: | セミコロン(;)で区切られた値: |
| 値1 - スタイルと開始 "番号" を表す文字列 | |
| 例:. "." (中黒), "1)","(b)", "C.", "iv", "V)" | |
| 末尾のスペースは番号と段落の間の最も小さいスペースを表します。 | |
| 特殊な場合: | |
| "=" - この段落は直前のリスト要素内で番号付けされていない段落です。 | |
| "" - 選択された段落から番号付けが取り除かれています。 | |
| 値2 - ローマ数字の場合"Roman"、それ以外の場合"" | |
| 値3 - 番号/中黒と段落の間のスペース (スペースの単位) | |
| 値4 - 範囲: | |
| a - 選択された全て(または最初)の段落に設定されています。 | |
| f - 最初の選択された段落にのみ設定されています。 | |
| c - 現在の段落に設定されています。 | |
| 失敗: | ""を返し、@errorを設定します。 |
| @error: | 101 - $hWndがハンドルではありません。 |
注意
関連
_GUICtrlRichEdit_SetParaNumbering
こちらも参照
MSDNライブラリでEM_GETPARAFORMATを検索して下さい。
例
#AutoIt3Wrapper_Au3Check_Parameters= -d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Global $lblMsg, $hRichEdit
Main()
Func Main()
Local $hGui, $iMsg, $btnNext, $iStep = 0
$hGui = GUICreate("Example (" & StringTrimRight(@ScriptName,4) &")", 320, 350, -1, -1)
$hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
$lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
$btnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
GUISetState()
_GuiCtrlRichEdit_SetText($hRichEdit, "First paragraph")
_GuiCtrlRichEdit_SetSel($hRichEdit, 0, 1)
Report("Para with default indent settings")
While True
$iMsg = GUIGetMsg()
Select
Case $iMsg = $GUI_EVENT_CLOSE
GUIDelete()
Exit
Case $iMsg = $btnNext
$iStep += 1
Switch $iStep
Case 1
_GuiCtrlRichEdit_AppendText($hRichEdit, @CR & "Second paragraph")
_GUICtrlRichEdit_SetParaNumbering($hRichEdit, ".")
Report("Added second paragraph")
Case 2
_GuiCtrlRichEdit_SetSel($hRichEdit, 0, 2)
Report("Style of first paragraph in the selection")
Case 3
_GuiCtrlRichEdit_SetSel($hRichEdit, 10, 26)
_GUICtrlRichEdit_SetParaNumbering($hRichEdit, "v) ", Default, True)
Report("Change settings of both paragraphs")
Case 4
_GuiCtrlRichEdit_SetSel($hRichEdit, 10, 26)
_GUICtrlRichEdit_SetParaNumbering($hRichEdit, "2. ", Default, True)
Report("Changed settings for both paragraphs")
Case 5
; Wordで設定を確認できるように全てのテキストをデスクトップに保存
_GuiCtrlRichEdit_Deselect($hRichEdit)
_GuiCtrlRichEdit_StreamToFile($hRichEdit, @DesktopDir & "\gcre.rtf")
GUICtrlSetState($btnNext, $GUI_DISABLE)
EndSwitch
EndSelect
WEnd
EndFunc ;==>Main
Func Report($sMsg)
$sMsg = $sMsg & @CR & @CR & "Get function returns " & @CR & _GUICtrlRichEdit_GetParaNumbering($hRichEdit)
GUICtrlSetData($lblMsg, $sMsg)
EndFunc ;==>Report