現在選択されている段落の番号付けスタイルを設定します。選択されていない場合、挿入位置に挿入される段落の番号付けスタイルを設定します。
#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetParaNumbering($hWnd, $sStyle [, $iTextToNbrSpace = Default [, $fForceRoman=False]])
パラメータ
| $hWnd | コントロールのハンドル |
| $sStyle | スタイルと開始 "番号" を指定する文字列。例: "." (中黒), "1)","(b)", "C.", "iv", "V)" これは最初の段落に表示される"番号"です。 末尾のスペースはiTextToNbrSpaceが入力されない限りは番号と段落の間の最も小さいスペースを表します。 特殊なケース: "=" - 直前のリスト要素内の番号付けしない段落であることを表します。 "" - 選択されている段落の番号付けを削除します。 |
| $iTextToNbrSpace | [オプション] 番号/中黒と段落の間のスペース (スペースの単位) デフォルト: 末尾のスペースの数はポイントサイズの倍数です。 |
| $fForceRoman | [オプション] False - $sStyle内の i, v, x ... は i, v, x ... と書かれます(デフォルト)。 |
返し値
| 成功: | True |
| 失敗: | Falseを返し、@errorを設定します。 |
| @error: | 101 - $hWndがハンドルではありません。 |
| 102 - $sStyleが不正です。 | |
| 103 - $iTextToNbrSpaceが正の数ではありません。 | |
| 104 - $fForceRomanはTrueまたはFalseである必要があります。 |
注意
"スペースの単位"を設定するには_GUICtrlRichEdit_SetSpaceUnitを呼んで下さい。初期設定はインチです。
関連
_GUICtrlRichEdit_GetParaNumbering, _GUICtrlRichEdit_SetSpaceUnit
こちらも参照
MSDNライブラリでEM_SETPARAFORMATを検索して下さい。
例
#AutoIt3Wrapper_Au3Check_Parameters= -d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Global $lblMsg, $hRichEdit
Main()
Func Main()
Local $hGui, $iMsg, $btnNext, $iStep = 0
$hGui = GUICreate("Example (" & StringTrimRight(@ScriptName,4) &")", 320, 350, -1, -1)
$hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
$lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
$btnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
GUISetState()
_GuiCtrlRichEdit_SetText($hRichEdit, "First paragraph")
_GuiCtrlRichEdit_SetSel($hRichEdit, 0, 1)
Report("Para with default indent settings")
While True
$iMsg = GUIGetMsg()
Select
Case $iMsg = $GUI_EVENT_CLOSE
GUIDelete()
Exit
Case $iMsg = $btnNext
$iStep += 1
Switch $iStep
Case 1
_GuiCtrlRichEdit_AppendText($hRichEdit, @CR & "Second paragraph")
_GUICtrlRichEdit_SetParaNumbering($hRichEdit, ".")
Report("Added second paragraph")
Case 2
_GuiCtrlRichEdit_SetSel($hRichEdit, 0, 2)
Report("Style of first paragraph in the selection")
Case 3
_GuiCtrlRichEdit_SetSel($hRichEdit, 10, 26)
_GUICtrlRichEdit_SetParaNumbering($hRichEdit, "v) ", Default, True)
Report("Change settings of both paragraphs")
Case 4
_GuiCtrlRichEdit_SetSel($hRichEdit, 10, 26)
_GUICtrlRichEdit_SetParaNumbering($hRichEdit, "2. ", Default, True)
Report("Changed settings for both paragraphs")
Case 5
; Wordで設定を確認できるように全てのテキストをデスクトップに保存
_GuiCtrlRichEdit_Deselect($hRichEdit)
_GuiCtrlRichEdit_StreamToFile($hRichEdit, @DesktopDir & "\gcre.rtf")
GUICtrlSetState($btnNext, $GUI_DISABLE)
EndSwitch
EndSelect
WEnd
EndFunc ;==>Main
Func Report($sMsg)
$sMsg = $sMsg & @CR & @CR & "Get function returns " & @CR & _GUICtrlRichEdit_GetParaNumbering($hRichEdit)
GUICtrlSetData($lblMsg, $sMsg)
ControlFocus($hRichEdit, "", "")
EndFunc ;==>Report