選択されているテキストのある段落のタブストップを設定します。選択されていない場合、挿入位置に挿入される段落のタブストップを設定します。
#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetParaTabStops($hWnd, $sTabStops)
パラメータ
| $hWnd | コントロールのハンドル |
| $sTabStops | ; (セミコロン)で区切られたグループからなる文字列。グループの書式は以下の通りです:: タブストップの絶対位置 (スペースの単位) タブの種類 l - 左タブ c - 中央タブ r - 小数点タブ b - バータブ リーダーの種類 . - ドットのリーダー - - ダッシュのリーダー _ - 下線のリーダー = - 二重線のリーダー t - 太線のリーダー スペース - リーダー無し |
返し値
| 成功: | True |
| 失敗: | Falseを返し、@errorを設定します。 |
| @error: | 101 - $hWndがハンドルではありません。 |
| 1021 - タブストップの絶対位置が不明、または不正です。 | |
| 1022 - タブの種類が不明、または不正です。 | |
| 1023 - リーダーの種類が不明、または不正です。 | |
| 1024 - 設定しようとしているタブストップが多すぎます。 | |
| @extended にはエラーが起きた$sTabStops内のタブ番号が設定されます。 |
注意
タブストットプをリセットするには_GUICtrlRichEdit_SetParaTabStops($hWnd, "")を呼んで下さい。
関連
_GUICtrlRichEdit_GetParaTabStops, _GUICtrlRichEdit_SetSpaceUnit, _GUICtrlRichEdit_SetTabStops
こちらも参照
MSDNライブラリでEM_SETCHARFORMATを検索して下さい。
例
#AutoIt3Wrapper_Au3Check_Parameters= -d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Global $lblMsg, $hRichEdit
Main()
Func Main()
Local $hGui, $iMsg, $btnNext, $iStep = 0
$hGui = GUICreate("Example (" & StringTrimRight(@ScriptName,4) &")", 320, 350, -1, -1)
$hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
$lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
$btnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
GUISetState()
_GuiCtrlRichEdit_SetText($hRichEdit, "First paragraph")
Report("0. Para with default settings")
While True
$iMsg = GUIGetMsg()
Select
Case $iMsg = $GUI_EVENT_CLOSE
GUIDelete()
Exit
Case $iMsg = $btnNext
$iStep += 1
Switch $iStep
Case 1
_GuiCtrlRichEdit_AppendText($hRichEdit, @CR & "Second paragraph")
_GUICtrlRichEdit_SetParaTabStops($hRichEdit, ".3l ;1c ;2.5r.")
Report("1. TabStops of second paragraph")
Case 2
_GuiCtrlRichEdit_SetSel($hRichEdit, 0, 2)
Report("2. Tabstops of first paragraph")
Case 3
_GuiCtrlRichEdit_SetSel($hRichEdit, 10, 26)
Report("Tabstops of first paragraph in selection")
Case 4
_GUICtrlRichEdit_SetParaTabStops($hRichEdit, "2.3r=")
Report("3. Change tabstops of both paragraphs")
Case 5
; Wordで設定を確認できるように全てのテキストをデスクトップに保存
_GuiCtrlRichEdit_Deselect($hRichEdit)
_GuiCtrlRichEdit_StreamToFile($hRichEdit, @DesktopDir & "\gcre.rtf")
GUICtrlSetState($btnNext, $GUI_DISABLE)
EndSwitch
EndSelect
WEnd
EndFunc ;==>Main
Func Report($sMsg)
$sMsg = $sMsg & @CR & @CR & "Get function returns " & @CR & _GUICtrlRichEdit_GetParaTabStops($hRichEdit)
GUICtrlSetData($lblMsg, $sMsg)
ControlFocus($hRichEdit, "", "")
EndFunc ;==>Report