コントロールのタブストップを設定します。
#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetTabStops($hWnd, $vTabStops[, $fRedraw = True])
パラメータ
| $hWnd | コントロールのハンドル |
| $VTabStops | 設定するタブストップ(スペースの単位): 文字列の場合はセミコロンで区切られたタブストップ位置 数値の場合はスペース単位で指定数値<n>分のタブストップが設定されます。 |
| $fRedraw | [オプション] コントロールを再描画するかどうか - True(デフォルト)またはFalse |
返し値
| 成功: | True |
| 失敗: | Falseを返し、@errorを設定します。 |
| @error: | 101 - $hWndがハンドルではありません。 |
| 1021 - $vTabStopsが文字列でも数値でもありません。 | |
| 1022 - $vTabStopsが文字列ですがその内部のタブストップが正の数ではありません。 | |
| 1023 - $vTabStopsが空文字列です。 | |
| 1024 - $vTabStopsが数値ですがゼロまたは負の数です。 | |
| 103 - $fRedrawはTrueまたはFalseである必要があります。 |
注意
スペースの単位の初期値はインチです。 コントロールにタブを入力するにはCtrl_Tabを押して下さい。
関連
_GUICtrlRichEdit_SetParaTabStops, _GUICtrlRichEdit_SetSpaceUnit
こちらも参照
MSDNライブラリでEM_SETTABSTOPSを検索して下さい。
例
#AutoIt3Wrapper_Au3Check_Parameters= -d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Global $lblMsg, $hRichEdit
Main()
Func Main()
Local $hGui, $iMsg, $btnNext, $iStep = 0
$hGui = GUICreate("Example (" & StringTrimRight(@ScriptName,4) &")", 320, 350, -1, -1)
$hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
$lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
$btnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
GUISetState()
_GuiCtrlRichEdit_SetText($hRichEdit, "Paragraph 1")
While True
$iMsg = GUIGetMsg()
Select
Case $iMsg = $GUI_EVENT_CLOSE
GUIDelete()
Exit
Case $iMsg = $btnNext
$iStep += 1
Switch $iStep
Case 1
_GuiCtrlRichEdit_SetTabStops($hRichEdit, 1)
GUICtrlSetData($lblMsg, "1. Set tab stops every inch")
Case 2
_GuiCtrlRichEdit_SetTabStops($hRichEdit, "0.5;1.5")
GUICtrlSetData($lblMsg, "2. Set tab stops at 0.5 and 1.5 inches")
; Wordで設定を確認できるように全てのテキストをデスクトップに保存
_GUICtrlRichEdit_Deselect($hRichEdit)
_GuiCtrlRichEdit_StreamToFile($hRichEdit, @DesktopDir & "\gcre.rtf")
GUICtrlSetState($btnNext, $GUI_DISABLE)
EndSwitch
EndSelect
WEnd
EndFunc ;==>Main