Function Reference

_GUICtrlTab_GetItemImage

タブの画像インデックスを取得します。

#Include <GuiTab.au3>
_GUICtrlTab_GetItemImage($hWnd, $iIndex)

 

パラメータ

$hWnd コントロールのハンドル
$iIndex ゼロ始まりのアイテムインデックス

 

返し値

成功: タブのゼロ始まりの画像インデックス

 

注意

なし。

 

関連

_GUICtrlTab_SetItemImage

 


#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiConstantsEx.au3>
#include <GuiTab.au3>
#include <GuiImageList.au3>

Opt('MustDeclareVars', 1)

$Debug_TAB = False ; 関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用

_Main()

Func _Main()
    Local $hGUI, $hImage, $hTab

    ; GUIを作成
    $hGUI = GUICreate("Tab Control Get Item Image", 400, 300)
    $hTab = GUICtrlCreateTab(2, 2, 396, 296)
    GUISetState()

    ; 画像を作成
    $hImage = _GUIImageList_Create()
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0x0000FF, 16, 16))
    _GUICtrlTab_SetImageList($hTab, $hImage)

    ; タブを追加
    _GUICtrlTab_InsertItem($hTab, 0, "Tab 1")
    _GUICtrlTab_InsertItem($hTab, 1, "Tab 2")
    _GUICtrlTab_InsertItem($hTab, 2, "Tab 3")
   
    ; タブ2の画像を取得/設定
    _GUICtrlTab_SetItemImage($hTab, 1, 1)
    MsgBox(4160, "Information", "Tab 2 image index: " & _GUICtrlTab_GetItemImage($hTab, 1))


    ; ユーザーが終了するまでループ
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main