Function Reference

_GUICtrlTreeView_Create

ツリービューコントロールを作成します。

#Include <GuiTreeView.au3>
_GUICtrlTreeView_Create($hWnd, $iX, $iY[, $iWidth=150[, $iHeight=150[, $iStyle=0x00000037[, $iExStyle=0x00000000]]]])

 

パラメータ

$$hWnd 親ウィンドウまたはオーナーウィンドウのハンドル
$iX コントロールの水平位置
$iY コントロールの垂直位置
$iWidth [オプション]コントロールの幅
$iHeight [オプション]コントロールの高さ
$iStyle [オプション]コントロールのスタイル:
$TVS_CHECKBOXES - アイテムのチェックボックスを有効にします。 チェックボックスは画像がアイテムに関連付けられている場合のみ表示されます。 このスタイルを設定するとコントロールはDrawFrameControlを使用して2つの画像を格納した状態画像リストを作成、設定します。 状態画像1は非チェックのボックス、状態画像2はチェックされているボックスです。 状態画像に0を設定することでチェックボックスを取り除くことができます。 Version 5.80ではアイテムに関連付けられた画像がない場合でもチェックボックスが表示されます。
$TVS_DISABLEDRAGDROP - コントロールが$TVN_BEGINDRAG通知メッセージを送信しないようにします。
$TVS_EDITLABELS - ユーザーがアイテムラベルを編集できるようにします
$TVS_FULLROWSELECT - 全行の選択ができるようにします。 選択されたアイテムの行全体がハイライトされ、アイテムの行の任意の位置をクリックすると選択されます。 このスタイルは$TVS_HASLINESスタイルと同時に使用することはできません。
$TVS_HASBUTTONS - 親アイテムの隣にプラス/マイナスボタンを表示します。 ユーザーはこのボタンをクリックすることで親アイテムの子アイテムリストを開閉できます。 ルートのアイテムにも適用するには$TVS_LINESATROOTも指定する必要があります。
$TVS_HASLINES - アイテムの階層表示に線を使用します。
$TVS_INFOTIP - $TVN_GETINFOTIP通知を送信してツールチップ情報を取得します。
$TVS_LINESATROOT - コントロールのルートのアイテムをつなぐ線を使用します。 この値は$TVS_HASLINESが指定されていない場合、無視されます。
$TVS_NOHSCROLL - コントロールの水平スクロールを無効にします。 コントロールには水平スクロールバーが表示されません。
$TVS_NONEVENHEIGHT - $TVM_SETITEMHEIGHTメッセージを使用してアイテムの高さを奇数値に設定にします。 デフォルトではアイテムの高さは偶数値です。
$TVS_NOSCROLL - コントロールの水平スクロール、垂直スクロールの両方を無効にします。
コントロールにはスクロールバーが表示されません。
$TVS_NOTOOLTIPS - ツールチップを無効にします。
$TVS_RTLREADING - テキストの表示方向を右から左にします。
$TVS_SHOWSELALWAYS - コントロールからフォーカスが外れた場合でも選択アイテムの選択状態が維持されるようにします。
$TVS_SINGLEEXPAND - 選択されているアイテムを開き、非選択のアイテムを選択によって閉じます。 選択されていてなおかつ閉じているアイテムをマウスでシングルクリックするとアイテムが開きます。 アイテムの選択中にCTRLキーが押されていると非選択状態のアイテムは閉じません。 Version 5.80でも選択されているアイテムを開き、非選択のアイテムを選択によって閉じます。 アイテムの選択中にCTRLキーが押されていると非選択状態のアイテムは閉じません。
$TVS_TRACKSELECT - ホットトラッキングを有効にします
デフォルト: $TVS_HASBUTTONS、 $TVS_HASLINES、 $TVS_LINESATROOT、 $TVS_DISABLEDRAGDROP、 $TVS_SHOWSELALWAYS
強制:$WS_CHILD、 $WS_VISIBLE
$iExStyle [オプション]コントロール拡張スタイル

 

返し値

成功: コントロールのハンドル
失敗: 0

 

注意

この関数は上級者、コントロール動作学習用です。

 

関連

_GUICtrlTreeView_Destroy

 


#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiConstantsEx.au3>
#include <GuiTreeView.au3>
#include <WindowsConstants.au3>

Opt('MustDeclareVars', 1)

$Debug_TV = False ; 関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用

Global $hTreeView

_Main()

Func _Main()

    Local $GUI, $hItem
    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)
    $GUI = GUICreate("(UDF Created) TreeView Create", 400, 300)

    $hTreeView = _GUICtrlTreeView_Create($GUI, 2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState()

    GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")

    _GUICtrlTreeView_BeginUpdate($hTreeView)
    For $x = 1 To Random(2, 10, 1)
        $hItem = _GUICtrlTreeView_Add($hTreeView, 0, StringFormat("[%02d] New Item", $x))
        For $y = 1 To Random(2, 10, 1)
            _GUICtrlTreeView_AddChild($hTreeView, $hItem, StringFormat("[%02d] New Child", $y))
        Next
    Next
    _GUICtrlTreeView_EndUpdate($hTreeView)

    ; ユーザーが終了するまでループ
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main

Func WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam)
    #forceref $hWnd, $iMsg, $iwParam
    Local $hWndFrom, $iIDFrom, $iCode, $tNMHDR, $hWndTreeview
    $hWndTreeview = $hTreeView
    If Not IsHWnd($hTreeView) Then $hWndTreeview = GUICtrlGetHandle($hTreeView)

    $tNMHDR = DllStructCreate($tagNMHDR, $ilParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")
    Switch $hWndFrom
        Case $hWndTreeview
            Switch $iCode
                Case $NM_CLICK ; ユーザーがコントロールでマウス左ボタンをクリック
                    _DebugPrint("$NM_CLICK" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode)
;~                  Return 1 ; デフォルト処理を許可しない場合、非ゼロ
                    Return 0 ; デフォルト処理を許可する場合、ゼロ
                Case $NM_DBLCLK ; ユーザーがコントロールでマウス左ボタンをダブルクリック
                    _DebugPrint("$NM_DBLCLK" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode)
;~                  Return 1 ; デフォルト処理を許可しない場合、非ゼロ
                    Return 0 ; デフォルト処理を許可する場合、ゼロ
                Case $NM_RCLICK ; ユーザーがコントロールでマウス右ボタンをクリック
                    _DebugPrint("$NM_RCLICK" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode)
;~                  Return 1 ; デフォルト処理を許可しない場合、非ゼロ
                    Return 0 ; デフォルト処理を許可する場合、ゼロ
                Case $NM_RDBLCLK ; ユーザーがコントロールでマウス右ボタンをダブルクリック
                    _DebugPrint("$NM_RDBLCLK" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode)
;~                  Return 1 ; デフォルト処理を許可しない場合、非ゼロ
                    Return 0 ; デフォルト処理を許可する場合、ゼロ
                Case $NM_KILLFOCUS ; コントロールから入力フォーカスが外れた
                    _DebugPrint("$NM_KILLFOCUS" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode)
                    ; 返し値なし
                Case $NM_RETURN ; コントロールに入力フォーカスが合い、ユーザーがキーを押した
                    _DebugPrint("$NM_RETURN" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode)
;~                  Return 1 ; デフォルト処理を許可しない場合、非ゼロ
                    Return 0 ; デフォルト処理を許可する場合、ゼロ
;~              Case $NM_SETCURSOR ; コントロールにWM_SETCURSORメッセージに対するカーソルを設定中
;~                  Local $tinfo = DllStructCreate($tagNMMOUSE, $ilParam)
;~                  $hWndFrom = HWnd(DllStructGetData($tinfo, "hWndFrom"))
;~                  $iIDFrom = DllStructGetData($tinfo, "IDFrom")
;~                  $iCode = DllStructGetData($tinfo, "Code")
;~                  _DebugPrint("$NM_SETCURSOR" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
;~                          "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
;~                          "-->Code:" & @TAB & $iCode & @LF & _
;~                          "-->ItemSpec:" & @TAB & DllStructGetData($tinfo, "ItemSpec") & @LF & _
;~                          "-->ItemData:" & @TAB & DllStructGetData($tinfo, "ItemData") & @LF & _
;~                          "-->X:" & @TAB & DllStructGetData($tinfo, "X") & @LF & _
;~                          "-->Y:" & @TAB & DllStructGetData($tinfo, "Y") & @LF & _
;~                          "-->HitInfo:" & @TAB & DllStructGetData($tinfo, "HitInfo"))
;~                  Return 0 ; コントロールにカーソル設定できるようにする
;~                  Return 1 ; 非ゼロの場合、コントロールにカーソル設定できないようにする
                Case $NM_SETFOCUS ; コントロールに入力フォーカスが合った
                    _DebugPrint("$NM_SETFOCUS" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode)
                    ; 返し値なし
                Case $TVN_BEGINDRAGA, $TVN_BEGINDRAGW
                    _DebugPrint("$TVN_BEGINDRAG")
                Case $TVN_BEGINLABELEDITA, $TVN_BEGINLABELEDITW
                    _DebugPrint("$TVN_BEGINLABELEDIT")
                Case $TVN_BEGINRDRAGA, $TVN_BEGINRDRAGW
                    _DebugPrint("$TVN_BEGINRDRAG")
                Case $TVN_DELETEITEMA, $TVN_DELETEITEMW
                    _DebugPrint("$TVN_DELETEITEM")
                Case $TVN_ENDLABELEDITA, $TVN_ENDLABELEDITW
                    _DebugPrint("$TVN_ENDLABELEDIT")
                Case $TVN_GETDISPINFOA, $TVN_GETDISPINFOW
                    _DebugPrint("$TVN_GETDISPINFO")
                Case $TVN_GETINFOTIPA, $TVN_GETINFOTIPW
                    _DebugPrint("$TVN_GETINFOTIP")
                Case $TVN_ITEMEXPANDEDA, $TVN_ITEMEXPANDEDW
                    _DebugPrint("$TVN_ITEMEXPANDED")
                Case $TVN_ITEMEXPANDINGA, $TVN_ITEMEXPANDINGW
                    _DebugPrint("$TVN_ITEMEXPANDING")
                Case $TVN_KEYDOWN
                    _DebugPrint("$TVN_KEYDOWN")
                Case $TVN_SELCHANGEDA, $TVN_SELCHANGEDW
                    _DebugPrint("$TVN_SELCHANGED")
                Case $TVN_SELCHANGINGA, $TVN_SELCHANGINGW
                    _DebugPrint("$TVN_SELCHANGING")
                Case $TVN_SETDISPINFOA, $TVN_SETDISPINFOW
                    _DebugPrint("$TVN_SETDISPINFO")
                Case $TVN_SINGLEEXPAND
                    _DebugPrint("$TVN_SINGLEEXPAND")
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

Func _DebugPrint($s_text, $line = @ScriptLineNumber)
    ConsoleWrite( _
            "!===========================================================" & @LF & _
            "+======================================================" & @LF & _
            "-->Line(" & StringFormat("%04d", $line) & "):" & @TAB & $s_text & @LF & _
            "+======================================================" & @LF)
EndFunc   ;==>_DebugPrint