ツリーアイテムの外接長方形を返します。
#Include <GuiTreeView.au3>
_GUICtrlTreeView_DisplayRect($hWnd, $hItem[, $fTextOnly = False])
パラメータ
| $hWnd | コントロールのハンドル |
| $hItem | 長方形が返されるアイテムのハンドル |
| $fTextOnly | [オプション]Trueの場合、外接長方形はアイテムのテキストのみに対してのものです。 それ以外の場合はアイテムが占める領域全体に対するものです。 |
返し値
| 成功: | 次のフォーマットの配列: |
| $aRect[0] - 長方形の左上隅のX座標 | |
| $aRect[1] - 長方形の左上隅のY座標 | |
| $aRect[2] - 長方形の右下隅のX座標 | |
| $aRect[3] - 長方形の右下隅のY座標 | |
| 失敗: | @errorを設定します。 |
注意
なし。
関連
_GUICtrlTreeView_DisplayRectEx
例
#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiConstantsEx.au3>
#include <GuiTreeView.au3>
#include <GuiImageList.au3>
#include <WindowsConstants.au3>
Opt('MustDeclareVars', 1)
$Debug_TV = False ; 関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用
_Main()
Func _Main()
Local $hItem[6], $hImage, $aRect, $hTreeView
Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)
GUICreate("TreeView Display Rect", 400, 300)
$hTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
GUISetState()
$hImage = _GUIImageList_Create(16, 16, 5, 3)
_GUIImageList_AddIcon($hImage, "shell32.dll", 110)
_GUIImageList_AddIcon($hImage, "shell32.dll", 131)
_GUIImageList_AddIcon($hImage, "shell32.dll", 165)
_GUIImageList_AddIcon($hImage, "shell32.dll", 168)
_GUIImageList_AddIcon($hImage, "shell32.dll", 137)
_GUIImageList_AddIcon($hImage, "shell32.dll", 146)
_GUICtrlTreeView_SetNormalImageList($hTreeView, $hImage)
For $x = 0 To _GUIImageList_GetImageCount($hImage) - 1
$hItem[$x] = _GUICtrlTreeView_Add($hTreeView, 0, StringFormat("[%02d] New Item", $x + 1), $x, $x)
Next
$aRect = _GUICtrlTreeView_DisplayRect($hTreeView, $hItem[2])
MsgBox(4160, "Information", StringFormat("Item 2 Rectangle : [%d, %d, %d, %d]", $aRect[0], $aRect[1], $aRect[2], $aRect[3]))
; ユーザーが終了するまでループ
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>_Main