アイテムが開かれているかどうかを表します。
#Include <GuiTreeView.au3>
_GUICtrlTreeView_GetExpanded($hWnd, $hItem)
パラメータ
| $hWnd | コントロールのハンドル |
| $hItem | アイテムのハンドル |
返し値
| True: | アイテムは開かれています |
| False: | アイテムは開かれていません |
注意
なし。
関連
_GUICtrlTreeView_Expand
例
#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiConstantsEx.au3>
#include <GuiTreeView.au3>
#include <GuiImageList.au3>
#include <WindowsConstants.au3>
Opt('MustDeclareVars', 1)
$Debug_TV = False ; 関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用
_Main()
Func _Main()
Local $hItem[6], $hRandomItem, $hTreeView
Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)
GUICreate("TreeView Get Expanded", 400, 300)
$hTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
GUISetState()
_GUICtrlTreeView_BeginUpdate($hTreeView)
For $x = 0 To UBound($hItem) - 1
$hItem[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Item", $x), $hTreeView)
For $y = 0 To 2
GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Item", $y), $hItem[$x])
Next
Next
_GUICtrlTreeView_EndUpdate($hTreeView)
$hRandomItem = Random(0, UBound($hItem) - 1, 1)
MsgBox(4160, "Information", StringFormat("Item %d Expanded? %s", $hRandomItem, _GUICtrlTreeView_GetExpanded($hTreeView, $hItem[$hRandomItem])))
_GUICtrlTreeView_Expand($hTreeView, $hItem[$hRandomItem])
MsgBox(4160, "Information", StringFormat("Item %d Expanded? %s", $hRandomItem, _GUICtrlTreeView_GetExpanded($hTreeView, $hItem[$hRandomItem])))
; ユーザーが終了するまでループ
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>_Main