アイテムが選択状態で表示されているかどうかを表します。
#Include <GuiTreeView.au3>
_GUICtrlTreeView_GetSelected($hWnd, $hItem)
パラメータ
| $hWnd | コントロールのハンドル |
| $hItem | アイテムのハンドル |
返し値
| True: | アイテムは選択状態です |
| False: | アイテムは選択状態ではありません |
注意
なし。
関連
_GUICtrlTreeView_SetSelected
例
#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiConstantsEx.au3>
#include <GuiTreeView.au3>
#include <WindowsConstants.au3>
Opt('MustDeclareVars', 1)
$Debug_TV = False ; 関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用
_Main()
Func _Main()
Local $hItem[10], $iRand, $hTreeView
Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)
GUICreate("TreeView Get Selected", 400, 300)
$hTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
GUISetState()
_GUICtrlTreeView_BeginUpdate($hTreeView)
For $x = 0 To 9
$hItem[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Item", $x), $hTreeView)
For $y = 1 To Random(2, 10, 1)
GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Child", $y), $hItem[$x])
Next
Next
_GUICtrlTreeView_EndUpdate($hTreeView)
$iRand = Random(0, 9, 1)
MsgBox(4160, "Information", StringFormat("Index %d Selected? %s", $iRand, _GUICtrlTreeView_GetSelected($hTreeView, $hItem[$iRand])))
_GUICtrlTreeView_SetSelected($hTreeView, $hItem[$iRand])
MsgBox(4160, "Information", StringFormat("Index %d Selected? %s", $iRand, _GUICtrlTreeView_GetSelected($hTreeView, $hItem[$iRand])))
; ユーザーが終了するまでループ
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>_Main