インデックスを使用してアイテムのチェックボックスのチェック状態を設定します。
#Include <GuiTreeView.au3>
_GUICtrlTreeView_SetCheckedByIndex($hWnd, $hItem, $iIndex[, $fCheck = True])
パラメータ
| $hWnd | コントロールのハンドル |
| $hItem | アイテムのハンドル |
| $iIndex | $hItemのアイテムリスト内のゼロ始まりのインデックス |
| $fCheck | [オプション]チェック状態に設定する値: True - チェックします False - チェックをはずします |
返し値
| 成功: | True |
| 失敗: | False |
注意
なし。
関連
例
#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiConstantsEx.au3>
#include <GuiTreeView.au3>
#include <WindowsConstants.au3>
Opt('MustDeclareVars', 1)
$Debug_TV = False ; 関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用
_Main()
Func _Main()
Local $hItem[6], $hRandomItem, $iRandIndex, $hTreeView
Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)
GUICreate("TreeView Set Checked By Index", 400, 300)
$hTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
GUISetState()
_GUICtrlTreeView_BeginUpdate($hTreeView)
For $x = 0 To UBound($hItem) - 1
$hItem[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Item", $x + 1), $hTreeView)
For $y = 0 To 5
GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Child Item", $y + 1), $hItem[$x])
Next
Next
_GUICtrlTreeView_EndUpdate($hTreeView)
$hRandomItem = Random(0, UBound($hItem) - 1, 1)
$iRandIndex = Random(0, 5, 1)
MsgBox(4160, "Information", _
StringFormat("Set Child Item index[%d] of Item Index[%d]: %s", $iRandIndex, $hRandomItem, _
_GUICtrlTreeView_SetCheckedByIndex($hTreeView, $hItem[$hRandomItem], $iRandIndex)))
_GUICtrlTreeView_Expand($hTreeView)
; ユーザーが終了するまでループ
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>_Main