Function Reference

_GUICtrlTreeView_SetSelectedImageIndex

選択時画像のインデックスを設定します。

#Include <GuiTreeView.au3>
_GUICtrlTreeView_SetSelectedImageIndex($hWnd, $hItem, $iIndex)

 

パラメータ

$hWnd コントロールのハンドル
$hItem アイテムのハンドル
$iIndex 画像リストのインデックス

 

返し値

成功: True
失敗: False

 

注意

なし。

 

関連

_GUICtrlTreeView_GetSelectedImageIndex

 


#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiConstantsEx.au3>
#include <GuiTreeView.au3>
#include <GuiImageList.au3>
#include <WindowsConstants.au3>

Opt('MustDeclareVars', 1)

$Debug_TV = False ; 関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用

_Main()

Func _Main()

    Local $hItem[10], $hImage, $iImage, $iSImage, $iRand, $hTreeView
    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)

    GUICreate("TreeView Set Selected Image Index", 400, 300)

    $hTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState()

    $hImage = _GUIImageList_Create(16, 16, 5, 3)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 110)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 131)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 165)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 168)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 137)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 146)
    _GUICtrlTreeView_SetNormalImageList($hTreeView, $hImage)

    _GUICtrlTreeView_BeginUpdate($hTreeView)
    For $x = 0 To 5
        $hItem[$x] = _GUICtrlTreeView_Add($hTreeView, 0, StringFormat("[%02d] New Item", $x), $x, $x)
        For $y = 1 To Random(2, 10, 1)
            $iImage = Random(0, 5, 1)
            $iSImage = Random(0, 5, 1)
            _GUICtrlTreeView_AddChild($hTreeView, $hItem[$x], StringFormat("[%02d] New Child", $y), $iImage, $iSImage)
        Next
    Next
    _GUICtrlTreeView_EndUpdate($hTreeView)
   
    _GUICtrlTreeView_SelectItem($hTreeView, $hItem[2])
    MsgBox(4160, "Information", StringFormat("Selected Image Index for Item Index 2? %d", _GUICtrlTreeView_GetSelectedImageIndex($hTreeView, $hItem[2])))
    _GUICtrlTreeView_SetSelectedImageIndex($hTreeView, $hItem[2], 1)
    MsgBox(4160, "Information", StringFormat("Selected Image Index for Item Index 2? %d", _GUICtrlTreeView_GetSelectedImageIndex($hTreeView, $hItem[2])))
    _GUICtrlTreeView_SelectItem($hTreeView, $hItem[2])

    ; ユーザーが終了するまでループ
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main