指定されたアイテムの状態を設定します。
#Include <GuiTreeView.au3>
_GUICtrlTreeView_SetState($hWnd, $hItem[, $iState = 0[, $iSetState = 0]])
パラメータ
| $hWnd | コントロールのハンドル |
| $hItem | 状態設定をおこなうアイテムのID/ハンドル |
| $iState | [オプション]新しいアイテムの状態。次の1つまたは組み合わせです: $TVIS_SELECTED - アイテムを選択状態に設定します $TVIS_CUT - アイテムをカット&ペースト操作の一部に設定します $TVIS_DROPHILITED - アイテムをドラッグ&ドロップのターゲットに設定します $TVIS_BOLD - アイテムを太字にします $TVIS_EXPANDED - アイテムを展開します $TVIS_EXPANDEDONCE - アイテムの子アイテムリストの展開履歴を展開済みにします $TVIS_EXPANDPARTIAL - アイテムを部分展開に設定します |
| $iSetState | [オプション]アイテムに状態設定する場合はTrue、状態の設定解除をする場合はFalseを指定します |
返し値
| 成功: | True |
| 失敗: | False |
注意
状態値はBitOr($TVIS_SELECTED, $TVIS_BOLD)のようにBitOrすることで複数設定できます。
関連
_GUICtrlTreeView_GetState
例
#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiConstantsEx.au3>
#include <GuiTreeView.au3>
#include <GuiImageList.au3>
#include <WindowsConstants.au3>
Opt('MustDeclareVars', 1)
$Debug_TV = False ; 関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用
_Main()
Func _Main()
Local $hItem[10], $hImage, $iImage, $iRand, $hTreeView
Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)
GUICreate("TreeView Set State", 400, 300)
$hTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
GUISetState()
$hImage = _GUIImageList_Create(16, 16, 5, 3)
_GUIImageList_AddIcon($hImage, "shell32.dll", 110)
_GUIImageList_AddIcon($hImage, "shell32.dll", 131)
_GUIImageList_AddIcon($hImage, "shell32.dll", 165)
_GUIImageList_AddIcon($hImage, "shell32.dll", 168)
_GUIImageList_AddIcon($hImage, "shell32.dll", 137)
_GUIImageList_AddIcon($hImage, "shell32.dll", 146)
_GUICtrlTreeView_SetNormalImageList($hTreeView, $hImage)
_GUICtrlTreeView_BeginUpdate($hTreeView)
For $x = 0 To 9
$iImage = Random(0, 5, 1)
$hItem[$x] = _GUICtrlTreeView_Add($hTreeView, 0, StringFormat("[%02d] New Item", $x), $iImage, $iImage)
For $y = 1 To Random(2, 10, 1)
$iImage = Random(0, 5, 1)
_GUICtrlTreeView_AddChild($hTreeView, $hItem[$x], StringFormat("[%02d] New Child", $y), $iImage, $iImage)
Next
Next
_GUICtrlTreeView_EndUpdate($hTreeView)
$iRand = Random(0, 9, 1)
_GUICtrlTreeView_SetState($hTreeView, $hItem[$iRand], $TVIS_CUT)
MsgBox(4160, "Information", StringFormat("State for Index %d? %s", $iRand, _GUICtrlTreeView_GetState($hTreeView, $hItem[$iRand])))
; ユーザーが終了するまでループ
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>_Main