1つ以上の画像をイメージリストに追加します。
#Include <GuiImageList.au3>
_GUIImageList_Add($hWnd, $hImage[, $hMask=0])
パラメータ
| $hWnd | コントロールのハンドル |
| $hImage | 画像を格納しているビットマップのハンドル。 画像数は、ビットマップの幅から推測されます。 |
| $hMask | [オプション]マスクを格納しているビットマップのハンドル |
返し値
| 成功: | 1番目の新しい画像のインデックス |
| 失敗: | -1 |
注意
この関数はビットマップを内部のデータ構造体にコピーします。
関連
_GUIImageList_AddMasked, _GUIImageList_AddBitmap, _GUIImageList_AddIcon
例
#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiConstantsEx.au3>
#include <WinAPI.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>
#include <WindowsConstants.au3>
Opt('MustDeclareVars', 1)
_Main()
Func _Main()
Local $listview, $hImage
Local $exStyles = BitOR($LVS_EX_GRIDLINES, $LVS_EX_FULLROWSELECT, $LVS_EX_SUBITEMIMAGES)
GUICreate("ImageList Add", 400, 300)
$listview = GUICtrlCreateListView("", 2, 2, 394, 268, BitOR($LVS_SHOWSELALWAYS, $LVS_NOSORTHEADER, $LVS_REPORT))
_GUICtrlListView_SetExtendedListViewStyle($listview, $exStyles)
GUISetState()
; 画像をロード
$hImage = _GUIImageList_Create(11, 11)
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($listview, 0xFF0000, 11, 11))
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($listview, 0x00FF00, 11, 11))
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($listview, 0x0000FF, 11, 11))
_GUICtrlListView_SetImageList($listview, $hImage, 1)
; 列を追加
_GUICtrlListView_AddColumn($listview, "Items", 120)
; アイテムを追加
_GUICtrlListView_AddItem($listview, "Item 1", 0)
_GUICtrlListView_AddItem($listview, "Item 2", 1)
_GUICtrlListView_AddItem($listview, "Item 3", 2)
; ユーザーが終了するまでループ
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>_Main