スクロールバーのパラメータを取得します。
#Include <GuiScrollBars.au3>
_GUIScrollBars_GetScrollInfo($hWnd, $fnBar, ByRef $tSCROLLINFO)
パラメータ
| $hWnd | ウィンドウのハンドル |
| $fnBar | スクロールバーの種類を指定します。このパラメータは次の値のいずれかです: $SB_CTL - スクロールバーコントロールのパラメータを取得します。$hWndパラメータはスクロールバーコントロールのハンドルでなければなりません。 $SB_HORZ - ウィンドウの標準的な水平スクロールバーのパラメータを取得します。 $SB_VERT - ウィンドウの標準的な垂直スクロールバーのパラメータを取得します。 |
| $tSCROLLINFO | $tagSCROLLINFO構造体 |
返し値
| 成功: | True |
| 失敗: | False |
注意
上記の定数にはScrollBarConstants.au3が必要です。
関連
_GUIScrollBars_GetScrollInfoEx, $tagSCROLLINFO, _GUIScrollBars_SetScrollInfo
こちらも参照
MSDNライブラリでGetScrollInfoを検索して下さい。
例
#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <StructureConstants.au3>
#include <GUIScrollBars.au3>
#include <ScrollBarConstants.au3>
Opt("MustDeclareVars", 1)
Global $iMemo
_Main()
Func _Main()
Local $GUIMsg, $hGUI, $tSCROLLINFO = DllStructCreate($tagSCROLLINFO)
$hGUI = GUICreate("ScrollBar Example", 400, 400, -1, -1, BitOR($WS_MINIMIZEBOX, $WS_CAPTION, $WS_POPUP, $WS_SYSMENU, $WS_SIZEBOX))
$iMemo = GUICtrlCreateEdit("", 2, 2, 380, 360, BitOR($WS_HSCROLL, $WS_VSCROLL))
GUICtrlSetResizing($iMemo, $GUI_DOCKALL)
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
GUISetBkColor(0x88AABB)
GUISetState()
_GUIScrollBars_Init($hGUI)
DllStructSetData($tSCROLLINFO, "cbSize", DllStructGetSize($tSCROLLINFO))
DllStructSetData($tSCROLLINFO, "fMask", $_SCROLLBARCONSTANTS_SIF_ALL)
_GUIScrollBars_GetScrollInfo($hGUI, $SB_HORZ, $tSCROLLINFO)
MemoWrite("Horizontal" & @CRLF & "--------------------------------------")
MemoWrite("nPage....: " & DllStructGetData($tSCROLLINFO, "nPage"))
MemoWrite("nPos.....: " & DllStructGetData($tSCROLLINFO, "nPos"))
MemoWrite("nMin.....: " & DllStructGetData($tSCROLLINFO, "nMin"))
MemoWrite("nMax.....: " & DllStructGetData($tSCROLLINFO, "nMax"))
MemoWrite("nTrackPos: " & DllStructGetData($tSCROLLINFO, "nTrackPos"))
DllStructSetData($tSCROLLINFO, "cbSize", DllStructGetSize($tSCROLLINFO))
DllStructSetData($tSCROLLINFO, "fMask", $_SCROLLBARCONSTANTS_SIF_ALL)
_GUIScrollBars_GetScrollInfo($hGUI, $SB_VERT, $tSCROLLINFO)
$tSCROLLINFO = _GUIScrollBars_GetScrollInfoEx($hGUI, $SB_VERT)
MemoWrite(@CRLF & "Vertical" & @CRLF & "--------------------------------------")
MemoWrite("nPage....: " & DllStructGetData($tSCROLLINFO, "nPage"))
MemoWrite("nPos.....: " & DllStructGetData($tSCROLLINFO, "nPos"))
MemoWrite("nMin.....: " & DllStructGetData($tSCROLLINFO, "nMin"))
MemoWrite("nMax.....: " & DllStructGetData($tSCROLLINFO, "nMax"))
MemoWrite("nTrackPos: " & DllStructGetData($tSCROLLINFO, "nTrackPos"))
While 1
$GUIMsg = GUIGetMsg()
Switch $GUIMsg
Case $GUI_EVENT_CLOSE
ExitLoop
EndSwitch
WEnd
Exit
EndFunc ;==>_Main
; メモコントロールに1行書き込み
Func MemoWrite($sMessage)
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite