Function Reference

_IECreateEmbedded

GuiCtrlCreateObj()を使ってAutoIt GUIに埋め込むのに適したウェブブラウザオブジェクトを作成します。

#include <IE.au3>
_IECreateEmbedded ( )

パラメータ

なし。

返し値

成功:	ウェブブラウザオブジェクトの参照を返します。
失敗:	0を返し@ERRORを設定します
@Error:	0 ($_IEStatus_Success) = 正常終了
	1 ($_IEStatus_GeneralError) = 一般的なエラー

注意

親アプリケーションに埋めこまれるまではこのオブジェクトは動作できません(例えば_IENavigateを実行できません)。この制限のために　ブラウザは_IECreateで作成したブラウザのように自動で'about:blank'に移動しません。従ってブラウザを親アプリケーションに埋め込んだ後やロードしたドキュメントに依存する処理(e.g. _IEBodyWriteHTML)をおこなおうとする前には_IENavigateを使って'about:blank'に移動しなければなりません。

Internet Explorerオブジェクト(例えば_IECreateが返すもの)にはあって、このオブジェクトにはないプロパティがいくつかあります。例えばステータステキストやアドレスバーなどブラウザにはあって、埋め込みコントロールにはないものです。

GUICreate()でWindowsスタイル$WS_CLIPCHILDRENを使用しない場合、オブジェクトの表示/非表示を自分で管理しなければなりません。

このオブジェクトに対して_IEQuitを使うことはできません。オブジェクトは親GUIが破棄された際に破棄されます。

例

; *******************************************************
; 例 1 - 'Back'、'Forward'によって履歴境界外を参照しようとしても
;    スクリプトが中止しないようにCOMエラーを捕捉
;    (予測済みのCOMエラーはコンソールに送信される)
; *******************************************************
;
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <IE.au3>

_IEErrorHandlerRegister ()

$oIE = _IECreateEmbedded ()
GUICreate("Embedded Web control Test", 640, 580, _
(@DesktopWidth - 640) / 2, (@DesktopHeight - 580) / 2, _
$WS_OVERLAPPEDWINDOW + $WS_VISIBLE + $WS_CLIPSIBLINGS + $WS_CLIPCHILDREN)
$GUIActiveX = GUICtrlCreateObj($oIE, 10, 40, 600, 360)
$GUI_Button_Back = GUICtrlCreateButton("Back", 10, 420, 100, 30)
$GUI_Button_Forward = GUICtrlCreateButton("Forward", 120, 420, 100, 30)
$GUI_Button_Home = GUICtrlCreateButton("Home", 230, 420, 100, 30)
$GUI_Button_Stop = GUICtrlCreateButton("Stop", 340, 420, 100, 30)

GUISetState()       ;GUIを表示

_IENavigate ($oIE, "http://www.autoitscript.com")

;ユーザーがウィンドウを閉じるまで待機
While 1
$msg = GUIGetMsg()
Select
Case $msg = $GUI_EVENT_CLOSE
ExitLoop
Case $msg = $GUI_Button_Home
_IENavigate ($oIE, "http://www.autoitscript.com")
Case $msg = $GUI_Button_Back
_IEAction ($oIE, "back")
Case $msg = $GUI_Button_Forward
_IEAction ($oIE, "forward")
Case $msg = $GUI_Button_Stop
_IEAction ($oIE, "stop")
EndSelect
WEnd

GUIDelete()

Exit

IE管理一覧

AutoItUDFsドキュメント日本語訳 - トップ