GUI用のActiveXコントロールを作成します。
GUICtrlCreateObj ( ObjectVar, left, top [, width [, height ]] )
パラメータ
| ObjectVar | 既に開かれているオブジェクトを指す変数。 |
| left | コントロールの左端。-1を使用するとGUICoordModeに基づいて左端位置が計算されます。 |
| top | コントロールの上端。-1を使用するとGUICoordModeに基づいて上端位置が計算されます。 |
| width | [オプション] コントロールの幅(デフォルトは最後に使用された幅)。 |
| height | [オプション] コントロールの高さ(デフォルトは最後に使用された高さ)。 |
返し値
| 成功 | 新しく作成したコントロールの識別子(コントロールID)を返します。 |
| 失敗 | 0を返します。 |
注意
この関数は'ActiveX Control'、'Document Object'をGUI内に埋め込みます。
関連
ObjCreate, ObjGet, ObjEvent, IsObj
例
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Opt('MustDeclareVars', 1)
Example()
; シンプルな例 : AutoIt GUI内にインターネットエクスプローラのオブジェクトを埋め込む
;
; 参照: http://msdn.microsoft.com/workshop/browser/webbrowser/reference/objects/internetexplorer.asp
Func Example()
Local $oIE, $GUIActiveX, $GUI_Button_Back, $GUI_Button_Forward
Local $GUI_Button_Home, $GUI_Button_Stop, $msg
$oIE = ObjCreate("Shell.Explorer.2")
; 出力用にシンプルなGUIを作成
GUICreate("Embedded Web control Test", 640, 580, (@DesktopWidth - 640) / 2, (@DesktopHeight - 580) / 2, BitOR($WS_OVERLAPPEDWINDOW, $WS_CLIPSIBLINGS, $WS_CLIPCHILDREN))
$GUIActiveX = GUICtrlCreateObj ($oIE, 10, 40, 600, 360)
$GUI_Button_Back = GUICtrlCreateButton("Back", 10, 420, 100, 30)
$GUI_Button_Forward = GUICtrlCreateButton("Forward", 120, 420, 100, 30)
$GUI_Button_Home = GUICtrlCreateButton("Home", 230, 420, 100, 30)
$GUI_Button_Stop = GUICtrlCreateButton("Stop", 330, 420, 100, 30)
GUISetState() ; GUI表示
$oIE.navigate("http://www.autoitscript.com")
; ユーザーがウィンドウを閉じるまで待機
While 1
$msg = GUIGetMsg()
Select
Case $msg = $GUI_EVENT_CLOSE
ExitLoop
Case $msg = $GUI_Button_Home
$oIE.navigate("http://www.autoitscript.com")
Case $msg = $GUI_Button_Back
$oIE.GoBack
Case $msg = $GUI_Button_Forward
$oIE.GoForward
Case $msg = $GUI_Button_Stop
$oIE.Stop
EndSelect
WEnd
GUIDelete()
EndFunc ;==>Example