ブラウザ、DOM要素の選択されたプロパティを返します。
#include <IE.au3>
_IEPropertyGet ( ByRef $o_object, $s_property )
パラメータ
| $o_object | InternetExplorer.Applicationのオブジェクト変数またはDOM要素 |
| $s_property | プロパティ選択 (注意を参照) |
返し値
| 成功: | 選択されたプロパティの値 |
| 失敗: | 0を返し@ERRORを設定します |
| @Error: | 0 ($_IEStatus_Success) = 正常終了 |
| 3 ($_IEStatus_InvalidDataType) = 無効なデータ型 | |
| 4 ($_IEStatus_InvalidObjectType) = 無効なオブジェクト型 | |
| 5 ($_IEStatus_InvalidValue) = 無効な値 | |
| @Extended: | 無効なパラメータの番号が格納されています |
注意
より詳しい情報はMSDNを参照。| プロパティ | 説明 |
| "addressbar" | ブラウザアドレスバーの表示/非表示を表すブール値を取得します。 |
| "browserx" | ドキュメント要素の左上隅のx座標(ブラウザ相対座標)を取得します。 |
| "browsery" | ドキュメント要素の左上隅のy座標(ブラウザ相対座標)を取得します。 |
| "busy" | オブジェクトが移動操作中か、ダウンロード操作中かを表すブール値を取得します。 |
| "contenteditable" | オブジェクトがマウス、キーボードによって編集可能かを表すブール値を取得します。 |
| "fullscreen" | ブラウザがフルスクリーンモードか、通常ウィンドウモードかを表すブール値を取得します。 |
| "height" | ブラウザメインウィンドウまたはドキュメント要素の高さを取得します。 |
| "hwnd" | Internet Explorerメインウィンドウのハンドルを取得します。このハンドルはほとんどのAutoIt Win*関数で使用できます。 |
| "innerhtml" | 開始・終了要素タグを除く要素のレンダリングされているHTMLを取得します。 |
| "innertext" | 要素のレンダリングされているテキスト(タグを含まない)を取得します。通常、outertextと同じです。 |
| "isdisabled" | ユーザーがオブジェクトを操作できるかどうかを表す値を取得します。 |
| "left" | オブジェクトのメインウィンドウ左端のスクリーン座標をを取得します。 |
| "locationname" | Internet Explorerが現在表示しているリソースの名前を取得します。 |
| "locationurl" | Internet Explorerが現在表示しているリソースのURLを取得します。 |
| "menubar" | ブラウザのメニューバーが表示されているかを表すブール値を取得します。 |
| "offline" | ブラウザが現在オフラインモードかを表すブール値を取得します。 |
| "outertext" | 要素のレンダリングされているテキスト(タグを含まない)を取得します。通常、innertextと同じです。 |
| "outerhtml" | 開始・終了要素タグを含む要素のレンダリングされているHTMLを取得します。 |
| "readystate" | オブジェクトの準備状態を取得します。 |
| "referrer" | 現在ページのアクセス元ページのURL文字列を取得します(そのページ上のリンクを介してアクセスしている場合にのみ。その他の場合、文字列はNULL)。 |
| "resizable" | オブジェクトのサイズ変更が可能かを表す値を取得します。 |
| "screenx" | ブラウザまたはオブジェクトの左上隅のx座標(スクリーン相対座標)を取得します。 |
| "screeny" | ブラウザまたはオブジェクトの左上隅のy座標(スクリーン相対座標)を取得します。 |
| "silent" | ブラウザがダイアログボックス表示できるかどうかを表す値を取得します。 |
| "statusbar" | オブジェクトのステータスバーが表示されているかどうかを表す値を取得します。 |
| "statustext" | オブジェクトのステータスバーのテキストを取得します。 |
| "theatermode" | ブラウザがシアターモードかどうかを表すブール値を取得します。シアターモードではブラウザのメインウィンドウがスクリーン全体を占め、最小限のナビゲーションボタンのみのツールバーが表示されます。 |
| "title" | ドキュメントタイトルを取得します。これはウィンドウタイトルとは異なります。通常、ウィンドウタイトルはドキュメントタイトルから始まりますが、Windowsレジストリで指定された追加テキストがそれに付け加えられます。 |
| "toolbar" | ブラウザツールバーの表示/非表示を表すブール値を取得します。 |
| "top" | オブジェクトメインウィンドウの上端のスクリーン座標を取得します。 |
| "visible" | オブジェクトの表示/非表示を表す値を取得します。 |
| "width" | ブラウザメインウィンドウまたはドキュメント要素の幅を取得します。 |
| "uniqueid" | DOMによって割り当てられた全要素に対してユニークなIDを取得します。このIDは要素IDが必要な場合に使用することができます。 |
| プロパティ | 説明 |
| "appcodename" | ブラウザのコードネームを取得します(プロパティのデフォルト値はMozilla)。 |
| "appminorversion" | アプリケーションのマイナーバージョン値を取得します。 |
| "appname" | ブラウザ名を取得します(プロパティのデフォルト値はMicrosoft Internet Explorer)。 |
| "appversion" | プラットフォームとブラウザのバージョンを取得します。 |
| "browserlanguage" | 現在のブラウザの言語設定を取得します(次の中のいずれかです。Language Codes)。 |
| "cookieenabled" | クライアントサイドの永続的なCookieがブラウザで有効かどうか取得します。永続的なCookieはクライアントサイドのコンピュータに保存されるものです。 |
| "cpuclass" | CPUのクラスを表す文字列を取得します(返し値はこちら)。 |
| "javaenabled" | Javaが有効かどうかを返します。 |
| "online" | システムがグローバルオフラインモードかどうかを取得します。 |
| "platform" | ユーザーのオペレーティングシステム名を取得します。(返し値はこちら)。 |
| "systemlanguage" | オペレーティングシステムが使用しているデフォルト言語を取得します(次の中のいずれかです。Language Codes)。 |
| "useragent" | HTTPユーザエージェント要求ヘッダーと同じ文字列を取得します。 |
| "userlanguage" | オペレーティングシステムの自然言語設定を取得します(次の中のいずれかです。Language Codes)。 |
| "vcard" | userProfileオブジェクト内の各属性が格納された配列が返されます(属性リストはこちら)。返し値は2次元配列です。1次元目は2つの要素を持ちます。1番目の要素(0)には属性名が、2番目の要素(1)には対応する値がはいっています。2次元目は29個の要素(0から28)を持ちます。 |
関連
_IEPropertySet, _IEBodyReadHTML, _IEBodyReadText, _IEBodyWriteHTML, _IEDocInsertHTML, _IEDocInsertText, _IEHeadInsertEventScript
例
; *******************************************************
; 例 1 - 基礎的なサンプルでブラウザを開く。アドレスバーが表示されているか調べ、
; 表示されていない場合は表示する
; *******************************************************
;
#include <IE.au3>
$oIE = _IE_Example ("basic")
If _IEPropertyGet ($oIE, "addressbar") Then
MsgBox(0, "AddressBar Status", "AddressBar Visible, turning it off")
_IEPropertySet ($oIE, "addressbar", False)
Else
MsgBox(0, "AddressBar Status", "AddressBar Invisible, turning it on")
_IEPropertySet ($oIE, "addressbar", True)
EndIf
; *******************************************************
; 例 2 - フォームのサンプルを開き、フォームのテキストエリア要素への参照を取得
; テキストエリアの座標と大きさを取得
; 外縁をマウスでなぞった後、マウスを中央に配置
; *******************************************************
;
$oIE = _IE_Example("form")
$oForm = _IEFormGetObjByName($oIE, "ExampleForm")
$oTextArea = _IEFormElementGetObjByName($oForm, "textareaExample")
; テキストエリアの座標と大きさを取得
$iScreenX = _IEPropertyGet($oTextArea, "screenx")
$iScreenY = _IEPropertyGet($oTextArea, "screeny")
$iBrowserX = _IEPropertyGet($oTextArea, "browserx")
$iBrowserY = _IEPropertyGet($oTextArea, "browserY")
$iWidth = _IEPropertyGet($oTextArea, "width")
$iHeight = _IEPropertyGet($oTextArea, "height")
; 外縁をマウスでなぞった後、マウスを中央に配置
MouseMove($iScreenX, $iScreenY)
MouseMove($iScreenX + $iWidth, $iScreenY)
MouseMove($iScreenX + $iWidth, $iScreenY + $iHeight)
MouseMove($iScreenX, $iScreenY + $iHeight)
MouseMove($iScreenX, $iScreenY)
MouseMove($iScreenX + $iWidth/2, $iScreenY + $iHeight/2)