選択範囲の最大文字間位置、最小文字間位置を取得します。
#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetSel($hWnd)
パラメータ
| $hWnd | コントロールのハンドル |
返し値
| 成功: | [<最小>, <最大>]の形式の配列 |
| 失敗: | @errorを設定します。 |
| @error: | 101 - $hWndがハンドルではありません。 |
注意
テキストの最初の文字は文字間位置0の次です。
関連
_GUICtrlRichEdit_SetSel, _GUICtrlRichEdit_GetSelText, _GUICtrlRichEdit_GetSelAA, _GUICtrlRichEdit_GetTextInLine, _GUICtrlRichEdit_Deselect, _GUICtrlRichEdit_IsTextSelected
こちらも参照
MSDNライブラリでEM_EXGETSELを検索して下さい。
例
#AutoIt3Wrapper_Au3Check_Parameters= -d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Opt('MustDeclareVars', 1)
Global $lblMsg, $hRichEdit
Main()
Func Main()
Local $hGui, $iMsg, $btnNext, $iStep = 0
$hGui = GUICreate("Example (" & StringTrimRight(@ScriptName,4) & ")", 320, 350, -1, -1)
$hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
$lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
$btnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
GUISetState()
_GuiCtrlRichEdit_SetSel($hRichEdit, 2 , 10)
While True
$iMsg = GUIGetMsg()
Select
Case $iMsg = $GUI_EVENT_CLOSE
GUIDelete()
Exit
Case $iMsg = $btnNext
$iStep += 1
Switch $iStep
Case 1
Report("1. Text is selected from inter-character position")
Case 2
_GuiCtrlRichEdit_DeSelect($hRichEdit)
Report("2. No text is selected now")
GUICtrlSetState($btnNext, $GUI_DISABLE)
EndSwitch
EndSelect
WEnd
EndFunc ;==>Main
Func Report($sMsg)
Local $aPos = _GuiCtrlRichEdit_GetSel($hRichEdit)
$sMsg = $sMsg & @CR & @CR & "Get function returns " & $aPos[0] & "," & $aPos[1]
GUICtrlSetData($lblMsg, $sMsg)
ControlFocus($hRichEdit, "", "")
EndFunc ;==>Report