GUI用のインプットコントロールを作成します。
GUICtrlCreateInput ( "text", left, top [, width [, height [, style [, exStyle]]]] )
パラメータ
| text | コントロールのテキスト。 |
| left | コントロールの左端。-1を使用するとGUICoordModeに基づいて左端位置が計算されます。 |
| top | コントロールの上端。-1を使用するとGUICoordModeに基づいて上端位置が計算されます。 |
| width | [オプション] コントロールの幅(デフォルトは最後に使用された幅)。 |
| height | [オプション] コントロールの高さ(デフォルトは最後に使用された高さ)。 |
| style |
[オプション] コントロールのスタイルを定義。GUIコントロールスタイル付録を参照。 デフォルト ( -1) : $ES_LEFT、$ES_AUTOHSCROLL 強制適用されるスタイル : $ES_READONLYが設定されていない場合、$WS_TABSTOP。$ES_MULTILINEは常にリセットされています。 |
| exStyle | [オプション] コントロールの拡張スタイルを定義。拡張スタイル表を参照。 |
返し値
| 成功 | 新しく作成したコントロールの識別子(コントロールID)を返します。 |
| 失敗 | 0を返します。 |
注意
コントロールの値を取得する方法についてはGUICtrlReadを参照。
関連
GUICoordMode (Option), GUICtrlUpdate..., GUIGetMsg, GUICtrlRead, GUICtrlCreateUpdown, GUICtrlSetLimit
例
#include <GUIConstantsEx.au3>
Opt('MustDeclareVars', 1)
Example()
Func Example()
Local $file, $btn, $msg
GUICreate(" My GUI input acceptfile", 320, 120, @DesktopWidth / 2 - 160, @DesktopHeight / 2 - 45, -1, 0x00000018); WS_EX_ACCEPTFILES
$file = GUICtrlCreateInput("", 10, 5, 300, 20)
GUICtrlSetState(-1, $GUI_DROPACCEPTED)
GUICtrlCreateInput("", 10, 35, 300, 20) ; ドラッグ&ドロップでのファイル入力不可
$btn = GUICtrlCreateButton("Ok", 40, 75, 60, 20)
GUISetState()
$msg = 0
While $msg <> $GUI_EVENT_CLOSE
$msg = GUIGetMsg()
Select
Case $msg = $btn
ExitLoop
EndSelect
WEnd
MsgBox(4096, "drag drop file", GUICtrlRead($file))
EndFunc ;==>Example