Function Reference

GUICtrlCreateLabel

GUI用の静的ラベルを作成します。

GUICtrlCreateLabel ( "text", left, top [, width [, height [, style [, exStyle]]]] )

 

パラメータ

text コントロールのテキスト。
left コントロールの左端。-1を使用するとGUICoordModeに基づいて左端位置が計算されます。
top コントロールの上端。-1を使用するとGUICoordModeに基づいて上端位置が計算されます。
width [オプション] コントロールの幅(デフォルトではテキストの幅に合わせて自動調整されます)。
height [オプション] コントロールの高さ(デフォルトではテキストの高さに合わせて自動調整されます)。
style [オプション] コントロールのスタイルを定義。GUIコントロールスタイル付録を参照。
デフォルト ( -1) : 無し。
強制適用されるスタイル : $SS_NOTIFY、$SS_LEFT
exStyle [オプション] コントロールの拡張スタイルを定義。拡張スタイル表を参照。

 

返し値

成功 新しく作成したコントロールの識別子(コントロールID)を返します。
失敗 0を返します。

 

注意

コントロールの情報を設定/変更する方法についてはGUICtrlUpdate...を参照。

デフォルトスタイルに他のスタイルを組み合わせる場合はBitOr($GUI_SS_DEFAULT_LABEL, newstyle,...)を使用してください。

上で指定されている値を使用するためにはスクリプトに#include <StaticConstants.au3>と書く必要があります。

デフォルトのサイズ変更方法は$GUI_DOCKAUTOで左上位置が基準になります。

拡張スタイル$GUI_WS_EX_PARENTDRAGを使用すると(GUICreateで$WS_CAPTIONスタイルを設定していない)タイトルバーの無いウィンドウ用の親ウィンドウのドラッギングが可能になります。

背景色を透明に設定するためにはGUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)を使用してください。

 

関連

GUICoordMode (Option), GUICtrlUpdate..., GUIGetMsg

 


#include <GUIConstantsEx.au3>

Opt('MustDeclareVars', 1)

Example()

Func Example()
    Local $widthCell, $msg, $iOldOpt
   
    GUICreate("My GUI")  ; 表示時に中央に表示されるダイアログボックスを作成

    GUISetHelp("notepad")  ; F1が押されるとメモ帳が実行
    $iOldOpt = Opt("GUICoordMode", 2)

    $widthCell = 70
    GUICtrlCreateLabel("Line 1 Cell 1", 10, 30, $widthCell) ; 最初のセル 幅70
    GUICtrlCreateLabel("Line 2 Cell 1", -1, 0) ; 次の行
    GUICtrlCreateLabel("Line 3 Cell 2", 0, 0) ; 次の行と次のセル
    GUICtrlCreateLabel("Line 3 Cell 3", 0, -1) ; 次のセル 同じ行
    GUICtrlCreateLabel("Line 4 Cell 1", -3 * $widthCell, 0) ; 次の行 セル1

    GUISetState()      ; 空のダイアログボックスを表示

    ; ダイアログが閉じられるまでGUIを実行
    Do
        $msg = GUIGetMsg()
    Until $msg = $GUI_EVENT_CLOSE

    $iOldOpt = Opt("GUICoordMode", $iOldOpt)
EndFunc   ;==>Example