GUI用のラジオボタンコントロールを作成します。
GUICtrlCreateRadio ( "text", left, top [, width [, height [, style [, exStyle]]]] )
パラメータ
| text | コントロールのテキスト。 |
| left | コントロールの左端。-1を使用するとGUICoordModeに基づいて左端位置が計算されます。 |
| top | コントロールの上端。-1を使用するとGUICoordModeに基づいて上端位置が計算されます。 |
| width | [オプション] コントロールの幅(デフォルトではテキストの幅に合わせて自動調整されます)。 |
| height | [オプション] コントロールの高さ(デフォルトではテキストの高さに合わせて自動調整されます)。 |
| style |
[オプション] コントロールのスタイルを定義。GUIコントロールスタイル付録を参照。 デフォルト ( -1) : なし。 強制適用されるスタイル : グループ内の最初のラジオには$BS_AUTORADIOBUTTONと$WS_TABSTOP。 |
| exStyle | [オプション] コントロールの拡張スタイルを定義。拡張スタイル表を参照。 |
返し値
| 成功 | 新しく作成したコントロールの識別子(コントロールID)を返します。 |
| 失敗 | 0を返します。 |
注意
コントロールの値を取得する方法についてはGUICtrlReadを参照。
関連
GUICoordMode (Option), GUICtrlUpdate..., GUIGetMsg
例
#include <GUIConstantsEx.au3>
Opt('MustDeclareVars', 1)
Example()
Func Example()
Local $radio1, $radio2, $msg
GUICreate("My GUI radio") ; 表示時に中央に表示されるダイアログボックスを作成
$radio1 = GUICtrlCreateRadio("Radio 1", 10, 10, 120, 20)
$radio2 = GUICtrlCreateRadio("Radio 2", 10, 40, 120, 20)
GUICtrlSetState($radio2, $GUI_CHECKED)
GUISetState() ; チェックボックスを1つ持つダイアログボックスを表示
; ダイアログが閉じられるまでGUIを実行
While 1
$msg = GUIGetMsg()
Select
Case $msg = $GUI_EVENT_CLOSE
ExitLoop
Case $msg = $radio1 And BitAND(GUICtrlRead($radio1), $GUI_CHECKED) = $GUI_CHECKED
MsgBox(64, 'Info:', 'You clicked the Radio 1 and it is Checked.')
Case $msg = $radio2 And BitAND(GUICtrlRead($radio2), $GUI_CHECKED) = $GUI_CHECKED
MsgBox(64, 'Info:', 'You clicked on Radio 2 and it is Checked.')
EndSelect
WEnd
EndFunc ;==>Example