Function Reference

_GUICtrlListView_GetItemEx

アイテムの属性の一部または全てを取得します。

#Include <GuiListView.au3>
_GUICtrlListView_GetItemEx($hWnd, ByRef $tItem)

 

パラメータ

$hWnd コントロールのハンドル
$tItem 取得する情報を指定する$tagLVITEM構造体

 

返し値

成功: True
失敗: False

 

注意

なし。

 

関連

_GUICtrlListView_GetItem, $tagLVITEM

 


#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiConstantsEx.au3>
#include <GuiListView.au3>

Opt('MustDeclareVars', 1)

$Debug_LV = False ; ListView関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用

_Main()

Func _Main()
    Local $tItem, $hListView
   
    GUICreate("ListView Get ItemEX", 400, 300)

    $hListView = GUICtrlCreateListView("Items", 2, 2, 394, 268)
    GUISetState()

    GUICtrlCreateListViewItem("Item 1", $hListView)
    GUICtrlCreateListViewItem("Item 2", $hListView)
    GUICtrlCreateListViewItem("Item 3", $hListView)

    ; アイテム1の状態を表示
    $tItem = DllStructCreate($tagLVITEM)
    DllStructSetData($tItem, "Mask", $LVIF_STATE)
    DllStructSetData($tItem, "Item", 1)
    DllStructSetData($tItem, "StateMask", -1)
    _GUICtrlListView_GetItemEx($hListView, $tItem)
    MsgBox(4160, "Information", "Item 2 State: " & DllStructGetData($tItem, "State"))
   
    ; アイテム2を選択
    _GUICtrlListView_SetItemSelected($hListView, 1)
   
    ; アイテム1の状態を表示
    _GUICtrlListView_GetItemEx($hListView, $tItem)
    MsgBox(4160, "Information", "Item 2 State: " & DllStructGetData($tItem, "State"))

    ; ユーザーが終了するまでループ
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main