GUI用の日付けコントロールを作成します。
GUICtrlCreateDate ( "text", left, top [, width [, height [, style [, exStyle]]]] )
パラメータ
| text | あらかじめ選択されている日付 ("yyyy/mm/dd"形式) |
| left | コントロールの左端。-1を使用するとGUICoordModeに基づいて左端位置が計算されます。 |
| top | コントロールの上端。-1を使用するとGUICoordModeに基づいて上端位置が計算されます。 |
| width | [オプション] コントロールの幅(デフォルトは最後に使用された幅)。 |
| height | [オプション] コントロールの高さ(デフォルトは最後に使用された高さ)。 |
| style | [オプション] コントロールのスタイルを定義。GUIコントロールスタイル付録を参照。
デフォルト (-1) ： $DTS_LONGDATEFORMAT 強制適用されるスタイル ： $WS_TABSTOP |
| exStyle | [オプション]
コントロールの拡張スタイルを定義。拡張スタイル表を参照。 デフォルト (-1) ： WS_EX_CLIENTEDGE |
返し値
| 成功 | 新しく作成したコントロールの識別子(コントロールID)を返します。 |
| 失敗 | 0を返します。 |
注意
コントロールの値を取得する方法についてはGUICtrlReadを参照。
関連
GUICoordMode (Option), GUICtrlSetState, GUIGetMsg, GUICtrlRead
例
#include <GUIConstantsEx.au3>
#include <DateTimeConstants.au3>
Opt('MustDeclareVars', 1)
Example1()
Example2()
Example3()
Example4()
; example1
Func Example1()
Local $date, $msg
GUICreate("My GUI get date", 200, 200, 800, 200)
$date = GUICtrlCreateDate("1953/04/25", 10, 10, 185, 20)
GUISetState()
; ダイアログが閉じられるまでGUIを実行
Do
$msg = GUIGetMsg()
Until $msg = $GUI_EVENT_CLOSE
MsgBox(0, "Date", GUICtrlRead($date))
GUIDelete()
EndFunc ;==>example1
; example2
Func Example2()
Local $n, $msg
GUICreate("My GUI get date", 200, 200, 800, 200)
$n = GUICtrlCreateDate("", 10, 10, 100, 20, $DTS_SHORTDATEFORMAT)
GUISetState()
; ダイアログが閉じられるまでGUIを実行
Do
$msg = GUIGetMsg()
Until $msg = $GUI_EVENT_CLOSE
MsgBox(0, "Date", GUICtrlRead($n))
GUIDelete()
EndFunc ;==>Example2
; example3
Func Example3()
Local $date, $DTM_SETFORMAT_, $style
GUICreate("My GUI get date", 200, 200, 800, 200)
$date = GUICtrlCreateDate("1953/04/25", 10, 10, 185, 20)
; 指定したデフォルトフォーマットを選択
$DTM_SETFORMAT_ = 0x1032 ; $DTM_SETFORMATW
$style = "yyyy/MM/dd HH:mm:ss"
GUICtrlSendMsg($date, $DTM_SETFORMAT_, 0, $style)
GUISetState()
While GUIGetMsg() <> $GUI_EVENT_CLOSE
WEnd
MsgBox(0, "Time", GUICtrlRead($date))
EndFunc ;==>Example3
; example4
Func Example4()
Local $n, $msg
GUICreate("My GUI get time", 200, 200, 800, 200)
$n = GUICtrlCreateDate("", 20, 20, 100, 20, $DTS_TIMEFORMAT)
GUISetState()
; ダイアログが閉じられるまでGUIを実行
Do
$msg = GUIGetMsg()
Until $msg = $GUI_EVENT_CLOSE
MsgBox(0, "Time", GUICtrlRead($n))
GUIDelete()
EndFunc ;==>Example4