Function Reference

GUICtrlCreateGraphic

GUI用のグラフィックコントロールを作成します。

GUICtrlCreateGraphic ( left, top [, width [, height [, style]]] )

パラメータ

left	コントロールの左端。-1を使用するとGUICoordModeに基づいて左端位置が計算されます。.
top	コントロールの上端。-1を使用するとGUICoordModeに基づいて上端位置が計算されます。
width	[オプション] コントロールの幅(デフォルトは最後に使用された幅)。
height	[オプション] コントロールの高さ(デフォルトは最後に使用された高さ)。
style	[オプション] コントロールのスタイルを定義。GUIコントロールスタイル付録を参照。デフォルト ( -1) ： $SS_NOTIFY.

返し値

成功	新しく作成したコントロールの識別子(コントロールID)を返します。
失敗	0を返します。

注意

コントロールでの描画についてはGUICtrlSetGraphicを参照してください。

枠と背景の色はGUICtrlSetBkColor、GUICtrlSetColorによって設定します。

グラフィックコントロールはクリックすることで他のコントロールとオーバーラップしないようにすることができます。オーバーラップが必要な場合はグラフィックコントロールを無効にしてください：GuiCtrlSetState(-1,$GUI_DISABLE)。

このコントロールは、グラフィック相対アドレッシングの作成を修正するためにサイズを変更することはできません。このコントロールは相対アドレス作成された画像を固定するためサイズ変更を行うことができません。ただしGUICtrlSetResizing()によって画像を切り詰めることは可能です。

例

#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>

Opt('MustDeclareVars', 1)

Global $MAXGr = 6, $del
Global $a[$MAXGr + 1] ; 0番目と$MAXGr番目の要素はGUICtrlDeleteの仕様上使うことができない。

Example()

Func Example()
Local $msg, $inc, $i

CreateChild()

$i = 1
$inc = 1
Do
$msg = GUIGetMsg()

If $msg = $del Then
GUICtrlDelete($a[$i])
$i = $i + $inc
If $i < 0 Or $i > $MAXGr Then Exit
EndIf
If $msg > 0 Then MsgBox(0, "clicked", $msg & @LF & $a[5], 2)
Until $msg = $GUI_EVENT_CLOSE
EndFunc ;==>Example

Func CreateChild()
Local $child
$child = GUICreate("My Draw")
$del = GUICtrlCreateButton("Delete", 50, 165, 50)

$a[1] = GUICtrlCreateGraphic(20, 50, 100, 100)
GUICtrlSetBkColor(-1, 0xffffff)
GUICtrlSetColor(-1, 0)

GUICtrlSetGraphic(-1, $GUI_GR_COLOR, 0xff0000, 0xff0000)
GUICtrlSetGraphic(-1, $GUI_GR_PIE, 50, 50, 40, 30, 270)
GUICtrlSetGraphic(-1, $GUI_GR_COLOR, 0x00ff00, 0xffffff)
GUICtrlSetGraphic(-1, $GUI_GR_PIE, 58, 50, 40, -60, 90)

GUICtrlSetGraphic(-1, $GUI_GR_ELLIPSE, 100, 100, 50, 80)
GUICtrlSetGraphic(-1, $GUI_GR_COLOR, 0x00ff00, 0xc0c0ff)
GUICtrlSetGraphic(-1, $GUI_GR_RECT, 350, 200, 50, 80)
GUICtrlCreateLabel("label", 65, 100, 30)
GUICtrlSetColor(-1, 0xff)

$a[2] = GUICtrlCreateGraphic(220, 50, 100, 100)
GUICtrlSetStyle(-1, $SS_NOTIFY)
GUICtrlSetGraphic(-1, $GUI_GR_COLOR, 0, 0xff)
GUICtrlSetGraphic(-1, $GUI_GR_PIE, 50, 50, 40, 30, 270)
GUICtrlSetGraphic(-1, $GUI_GR_COLOR, 0x00ff00, 0xffffff)
GUICtrlSetGraphic(-1, $GUI_GR_PIE, 58, 50, 40, -60, 90)

$a[3] = GUICtrlCreateGraphic(220, 150, 100, 100, 0)
GUICtrlSetBkColor(-1, 0xf08080)
GUICtrlSetColor(-1, 0xff)
GUICtrlSetGraphic(-1, $GUI_GR_COLOR, 0xff00)
GUICtrlSetGraphic(-1, $GUI_GR_RECT, 50, 50, 80, 80)

$a[4] = GUICtrlCreateGraphic(20, 200, 80, 80)
GUICtrlSetState(-1, $GUI_DISABLE)
GUICtrlSetBkColor(-1, 0xffffff)
GUICtrlSetGraphic(-1, $GUI_GR_MOVE, 10, 10)
GUICtrlSetGraphic(-1, $GUI_GR_COLOR, 0xff)
GUICtrlSetGraphic(-1, $GUI_GR_LINE, 30, 40)
GUICtrlSetGraphic(-1, $GUI_GR_COLOR, 0xff00)
GUICtrlSetGraphic(-1, $GUI_GR_LINE, 70, 70)
GUICtrlSetGraphic(-1, $GUI_GR_COLOR, 0xff0000)
GUICtrlSetGraphic(-1, $GUI_GR_LINE, 10, 50)
GUICtrlSetGraphic(-1, $GUI_GR_COLOR, 0xffff00)
GUICtrlSetGraphic(-1, $GUI_GR_LINE, 10, 10)

$a[5] = GUICtrlCreateGraphic(150, 10, 50, 50, 0)
GUICtrlSetBkColor(-1, 0xa0ffa0)
GUICtrlSetGraphic(-1, $GUI_GR_MOVE, 20, 20) ; 開始位置
; 各描画での色の切り替えを防ぐため
; 点の後に線を描画するのが好ましい
GUICtrlSetGraphic(-1, $GUI_GR_COLOR, 0x0000ff)
GUICtrlSetGraphic(-1, $GUI_GR_DOT, 30, 30)
GUICtrlSetGraphic(-1, $GUI_GR_COLOR, 0)
GUICtrlSetGraphic(-1, $GUI_GR_LINE, 20, 40)
GUICtrlSetGraphic(-1, $GUI_GR_COLOR, 0xff0000)
GUICtrlSetGraphic(-1, $GUI_GR_DOT, 25, 25)
GUICtrlSetGraphic(-1, $GUI_GR_COLOR, 0)
GUICtrlSetGraphic(-1, $GUI_GR_LINE, 40, 40)
GUICtrlSetGraphic(-1, $GUI_GR_DOT, 40, 40)

GUISetState()
EndFunc ;==>CreateChild

AutoIt関数一覧

AutoItドキュメント日本語訳 - トップ